ortp-git: add new package to [pcr]

1 files changed, 38 insertions, 0 deletions

diff --git a/pcr/ortp-git/PKGBUILD b/pcr/ortp-git/PKGBUILD
new file mode 100644
index 000000000..5b5d618e3
--- /dev/null
+++ b/pcr/ortp-git/PKGBUILD
@@ -0,0 +1,38 @@
+# Maintainer: André Silva <emulatorman@parabola.nu>
+
+_pkgname=ortp
+pkgname=ortp-git
+pkgver=r1667.14894ff
+pkgrel=1
+pkgdesc="A Real-time Transport Protocol (RTP) library"
+arch=('i686' 'x86_64')
+url="https://github.com/BelledonneCommunications/ortp"
+license=('LGPL2.1')
+makedepends=('git')
+depends=('glibc' 'bcunit-git' 'bctoolbox-git')
+conflicts=("${_pkgname}")
+provides=("${_pkgname}")
+source=("${_pkgname}-${pkgver}::git+https://github.com/BelledonneCommunications/ortp#branch=master")
+sha256sums=('SKIP')
+
+pkgver() {
+  cd $_pkgname-$pkgver
+  printf "r%s.%s" "$(git rev-list --count HEAD)" "$(git rev-parse --short HEAD)"
+}
+
+prepare() {
+  cd $_pkgname-$pkgver
+  ./autogen.sh
+}
+
+build() {
+  cd $_pkgname-$pkgver
+  ./configure --prefix=/usr \
+    --disable-strict
+  make
+}
+
+package() {
+  cd $_pkgname-$pkgver
+  make DESTDIR="${pkgdir}" install
+}