blob: 4f0735430a30819b5f9de24114281fdd0310169a (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
|
# $Id: PKGBUILD 147900 2015-11-28 09:47:14Z arojas $
# Maintainer (Arch): Timothy Redaelli <timothy.redaelli@gmail.com>
# Contributor (Arch): Andy Weidenbaum <archbaum@gmail.com>
# Maintainer: Márcio Silva <coadde@parabola.nu>
pkgname=bfgminer
pkgver=5.4.1
pkgrel=2.parabola1
pkgdesc="Bitcoin miner featuring overclocking, monitoring, fan speed control and remote management. For FPGA/GPU/CPU Bitcoin mining, with opencl-mesa recommendation"
arch=('i686' 'x86_64')
depends=('curl' 'jansson' 'libevent' 'libmicrohttpd' 'libusb' 'lm_sensors')
makedepends=('uthash' 'yasm')
optdepends=('opencl-mesa: OpenCL implementation for AMD/ATI GPUs')
replaces=("${pkgname}-libre" "${pkgname}-parabola")
conflicts=("${pkgname}-libre" "${pkgname}-parabola")
url='http://bfgminer.org/'
license=('GPL3')
source=(http://luke.dashjr.org/programs/bitcoin/files/$pkgname/$pkgver/$pkgname-$pkgver.txz
remove-dangerous-rpath.patch)
sha256sums=('1a0c3e43741d9061aa0b5257353a812b84632fc8ac7d5ec84d91fb134803cc0c'
'ec5289b837cc3b5de7f08603e4ae4d75cfff969a2389fd2aee036486f4aa7420')
prepare() {
cd $pkgname-$pkgver
patch -p1 -i "${srcdir}"/remove-dangerous-rpath.patch
}
build() {
cd $pkgname-$pkgver
./configure --prefix=/usr \
--sbindir=/usr/bin \
--enable-cpumining \
--enable-bfsb \
--enable-metabank \
--enable-scrypt \
--enable-opencl \
--with-udevrulesdir=/usr/lib/udev/rules.d
# --enable-knc (FS#33640)
make
}
package() {
cd $pkgname-$pkgver
make DESTDIR="$pkgdir" install
}
|
