blob: a60797d1683bcbdd41f3140f7093f8bdadc0aa51 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
|
# $Id: PKGBUILD 167838 2016-03-21 17:48:29Z bgyorgy $
# Maintainer (Arch): Balló György <ballogyor+arch at gmail dot com>
# Maintainer: André Silva <emulatorman@parabola.nu>
pkgname=gloobus-preview
_bzrrev=335
_bzrpath=~gloobus-dev/$pkgname/last_working_branch
pkgver=0.4.5.$_bzrrev
pkgrel=1.parabola1
pkgdesc="GNOME application designed to enable a full screen preview of any kind of file, with libarchive support"
arch=('i686' 'x86_64' 'armv7h')
url="http://gloobus.net/"
license=('GPL')
depends=('gst-plugins-base' 'gtksourceview3' 'poppler-glib' 'python-dbus' 'python-gobject')
makedepends=('boost' 'bzr' 'djvulibre' 'libgxps' 'libspectre')
replaces=(${pkgname}-libre)
conflicts=(${pkgname}-libre)
optdepends=('djvulibre: Preview DjVu documents'
'gst-libav: Extra media codecs'
'gst-plugins-bad: Extra media codecs'
'gst-plugins-good: Extra media codecs'
'gst-plugins-ugly: Extra media codecs'
'imagemagick: Support for more image formats'
'libgxps: Preview XPS documents'
'libspectre: Preview PostScript documents'
'unoconv: Preview LibreOffice compatible documents')
install=$pkgname.install
source=($pkgname-$_bzrrev.tar.gz::http://bazaar.launchpad.net/$_bzrpath/tarball/$_bzrrev
'gloobus-preview-usr-bsdtar-for-rar.patch')
sha256sums=('41f6a8935f74341b383e92661311d5e25c422c3fcebebdffa07e496412bef313'
'd9b2718b1584f55c5d714e7bba6c957f3e3653d76603c08526c8c8ea79275e80')
prepare() {
cd $_bzrpath
# Use bsdtar (libarchive) for RAR.
patch -Np1 -i "$srcdir/gloobus-preview-usr-bsdtar-for-rar.patch"
}
build() {
cd $_bzrpath
./autogen.sh --prefix=/usr
make
}
package() {
cd $_bzrpath
make DESTDIR="$pkgdir" install
}
|
