blob: ff876dfe8bf06dc7b803a8a05b0e42a18553077d (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
|
# $Id: PKGBUILD 144357 2011-12-05 03:44:51Z eric $
# Maintainer : Rémy Oudompheng <remy@archlinux.org>
# Contributor: Morgan LEFIEUX <comete@archlinuxfr.org>
# Contributor (Parabola): Jorge López <jorginho@adinet.com.uy>
_pkgname=hplip
pkgname=hplip-libre
pkgver=3.12.2
pkgrel=1
pkgdesc="Drivers for HP DeskJet, OfficeJet, Photosmart, Business Inkjet and some LaserJet"
arch=('i686' 'x86_64')
url="http://hplipopensource.com"
license=('GPL')
depends=('python2' 'ghostscript>=8.64-6' 'foomatic-db' 'foomatic-db-engine'
'net-snmp>=5.7.1')
makedepends=('python2-qt' 'python2-gobject2' 'sane' 'rpcbind' 'cups')
optdepends=('cups: for printing support'
'dbus-python: for dbus support'
'sane: for scanner support'
'python-imaging: for commandline scanning support'
'python-notify: for Desktop notification support'
'rpcbind: for network support'
'python2-qt: for running hp-toolbox'
'python2-gobject2: for running hp-toolbox')
replaces=('hpijs' "${_pkgname}")
conflicts=("${_pkgname}")
provides=("${_pkgname}=${pkgver}")
options=('!libtool')
install=hplip.install
source=(http://downloads.sourceforge.net/${_pkgname}/$_pkgname-$pkgver.tar.gz{,.asc})
sha1sums=('bdf3e37a344f5b57b62425f755c4293d6d4ae875'
'aa00cdf755fea38f39247a0a4a2e8241dc15112c')
build() {
cd "$srcdir/$_pkgname-$pkgver"
export PYTHON=python2
find . -type f -exec sed -i 's~^#.*env python~#!/usr/bin/env python2~' {} +
sed -i '1s|#!/usr/bin/python|#!/usr/bin/python2|' base/magic.py
sed -i 's|python ./print.py|python2 ./print.py|' scan.py
sed -i 's|python ./testpage.py|python2 ./testpage.py|' setup.py
sed -i 's|python ./setup.py|python2 ./setup.py|' ui4/devmgr5.py ui4/nodevicesdialog.py
sed -i 's|python %HOME%|python2 %HOME%|' base/utils.py
sed -i 's|python ./plugin.py|python2 ./plugin.py|' base/pkit.py
export AUTOMAKE='automake --foreign'
autoreconf --force --install
./configure --prefix=/usr \
--enable-qt4 \
--enable-foomatic-rip-hplip-install \
--enable-foomatic-ppd-install \
--enable-hpcups-install \
--enable-new-hpcups \
--enable-cups-ppd-install \
--enable-cups-drv-install \
--enable-hpijs-install \
--enable-foomatic-drv-install \
--enable-pp-build \
--enable-udev-acl-rules
make
}
package() {
cd "$srcdir/$_pkgname-$pkgver"
make rulesdir=/lib/udev/rules.d DESTDIR="$pkgdir/" install
# remove config provided by sane and autostart of hp-daemon
rm -rf "$pkgdir"/etc/{sane.d,xdg}
# remove HAL .fdi file because HAL is no longer used
rm -rf "$pkgdir"/usr/share/hal
}
|