blob: 6b8e8718df78968f677571c42c6aeec540247049 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
|
# Maintainer: Márcio Silva <coadde@parabola.nu>
# Contributor: André Silva <emulatorman@parabola.nu>
pkgbase=mesa
_pkgname=libcl
pkgname=$pkgbase-$_pkgname
pkgver=11.2.0
pkgrel=2
pkgdesc='Mesa 3-D OpenCL library and ICD loader'
arch=('i686' 'x86_64')
url="http://${pkgbase}3d.sourceforge.net"
license=('custom')
depends=("$pkgbase" 'libclc' 'libgcrypt' 'clang')
makedepends=('python2-mako' 'dri2proto' 'dri3proto' 'glproto' 'presentproto' 'python2' 'llvm')
provides=("$_pkgname" 'opencl-icd-loader')
conflicts=("$_pkgname" "$_pkgname-libre" 'opencl-nvidia' 'opencl-nvidia-304xx' 'ocl-icd')
replaces=("$_pkgname" "$_pkgname-libre" 'opencl-nvidia' 'opencl-nvidia-304xx')
source=(ftp://ftp.freedesktop.org/pub/$pkgbase/$pkgver/$pkgbase-$pkgver.tar.xz{,.sig})
sha512sums=('ce56d9669cb31f465b67fa056428f59c89b60480da1e0b3e293dc740a12ed2ead0574c356017c13dfb4666616843808b9a1b7501eac14fb774981739c7d363b7'
'SKIP')
validpgpkeys=('8703B6700E7EE06D7A39B8D6EDAE37B02CEB490D') # Emil Velikov <emil.l.velikov@gmail.com>
prepare() {
cd $srcdir/$pkgbase-$pkgver
# Fix detection of libLLVM when built with CMake
sed -i 's/LLVM_SO_NAME=.*/LLVM_SO_NAME=LLVM/' configure
}
build() {
cd $srcdir/$pkgbase-$pkgver
./configure --prefix=/usr \
--sysconfdir=/etc \
--with-gallium-drivers=r300,r600,radeonsi,nouveau,svga,swrast,virgl \
--with-egl-platforms=x11,drm,wayland \
--enable-llvm-shared-libs \
--enable-egl \
--enable-gallium-llvm \
--enable-opencl \
--with-clang-libdir=/usr/lib
make
# fake installation
mkdir $srcdir/fakeinstall
make DESTDIR=$srcdir/fakeinstall install
}
package() {
cd $srcdir/$pkgbase-$pkgver
install -vm755 -d $pkgdir/usr/lib/
cp -rv $srcdir/fakeinstall/usr/lib/libOpenCL* $pkgdir/usr/lib/
install -vm755 -d $pkgdir/usr/lib/gallium-pipe
cp -rv $srcdir/fakeinstall/usr/lib/gallium-pipe/pipe_{nouveau,r300,swrast,vmwgfx}.so $pkgdir/usr/lib/gallium-pipe/
install -vm755 -d $pkgdir/usr/share/licenses/$pkgname
install -vm644 docs/COPYING $pkgdir/usr/share/licenses/$pkgname
install -vm644 docs/license.html $pkgdir/usr/share/licenses/$pkgname/LICENSE
}
# vim:set ts=2 sw=2 et:
|
