blob: fed4d784ae84ba5aa5dd3796556b4c6458947ae0 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
|
# $Id$
# Maintainer: Thomas Bächler <thomas@archlinux.org>
# Maintainer: Tobias Powalowski <tpowa@archlinux.org>
# Maintainer (Parabola): André Silva <andre.paulista@adinet.com.uy>
pkgname=syslinux
pkgver=4.05
pkgrel=4.1
arch=('i686' 'x86_64')
pkgdesc="Collection of boot loaders that boot from FAT, ext2/3/4 and btrfs filesystems, from CDs and via PXE (Parabola rebranded)"
url="http://syslinux.zytor.com/"
license=('GPL2')
depends=('perl' 'glibc')
optdepends=('perl-passwd-md5: For md5pass'
'perl-digest-sha1: For sha1pass'
'mtools: For mkdiskimage and syslinux support'
)
makedepends=('nasm')
backup=('boot/syslinux/syslinux.cfg'
'boot/syslinux/splash.png')
install=syslinux.install
source=(http://www.kernel.org/pub/linux/utils/boot/syslinux/$pkgname-${pkgver}.tar.bz2
syslinux-dont-build-dos-windows-targets.patch
syslinux.cfg
syslinux-install_update
splash.png
fix-undefined-type-umode_t.patch)
md5sums=('82299242418385da1274c9479a778cb2'
'1528c376e43f0eaccaa80d8ad1bc13b4'
'8dc2afca3739667e892faf04eb97e7b1'
'680750f73dc2e587ac567d057d485813'
'0035b6cac6756a384b861eda8d33e4f7'
'75750bd5b0f5bc51920164a01a6f5f2e')
build() {
# Do not try to build syslinux with our default LDFLAGS, it will fail
unset LDFLAGS
cd "$srcdir"/$pkgname-${pkgver}
# Do not try to build the Windows or DOS installers
patch -p1 -i "$srcdir"/syslinux-dont-build-dos-windows-targets.patch
# Fix unknown type name 'umode_t' error
patch -p1 -i "$srcdir"/fix-undefined-type-umode_t.patch
# Fix FHS manpage path
sed 's|/usr/man|/usr/share/man|g' -i mk/syslinux.mk
make
}
package() {
cd "$srcdir"/$pkgname-${pkgver}
make INSTALLROOT="$pkgdir" AUXDIR=/usr/lib/syslinux install
# Install the default configuration
install -D -m644 "$srcdir"/syslinux.cfg "$pkgdir"/boot/syslinux/syslinux.cfg
# Install Parabola splash
install -D -m644 "$srcdir"/splash.png "$pkgdir"/boot/syslinux/splash.png
# Install the installation and update script
# This script is maintained at git://gist.github.com/772138.git
install -D -m755 "$srcdir"/syslinux-install_update "$pkgdir"/usr/sbin/syslinux-install_update
# move extlinux binary to /usr/sbin
mv "$pkgdir"/sbin/extlinux "$pkgdir"/usr/sbin/extlinux
}
|
