blob: 4967097b128de0c5a53d1235a4d0b18b2cf493fb (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
|
# Maintainer: Thomas Bächler <thomas@archlinux.org>
# Maintainer: Tobias Powalowski <tpowa@archlinux.org>
# Maintainer (Parabola): André Silva <emulatorman@lavabit.com>
pkgname=syslinux
pkgver=4.07
pkgrel=1
arch=('i686' 'x86_64')
pkgdesc="Collection of boot loaders that boot from FAT, ext2/3/4 and btrfs filesystems, from CDs and via PXE (Parabola rebranded)"
url="http://syslinux.zytor.com/"
license=('GPL2')
depends=('perl' 'glibc')
optdepends=('perl-passwd-md5: For md5pass'
'perl-digest-sha1: For sha1pass'
'mtools: For mkdiskimage and syslinux support'
'gptfdisk: For GPT support'
'util-linux: For isohybrid')
makedepends=('nasm')
backup=('boot/syslinux/syslinux.cfg'
'boot/syslinux/splash.png')
install=syslinux.install
source=(http://www.kernel.org/pub/linux/utils/boot/syslinux/$pkgname-${pkgver}.tar.bz2
syslinux-dont-build-dos-windows-targets.patch
syslinux.cfg
syslinux-install_update
splash.png)
md5sums=('9ff6e1b94efab931fb4717b600d88779'
'1528c376e43f0eaccaa80d8ad1bc13b4'
'83649111686c4c58ec05eac324ae711a'
'8559fb3daf3afa8688600d8a38118918'
'cb46ca47c6b6323127d908440057d98f')
build() {
# Do not try to build syslinux with our default LDFLAGS, it will fail
unset LDFLAGS
cd "$srcdir"/$pkgname-${pkgver}
# Do not try to build the Windows or DOS installers
patch -p1 -i "$srcdir"/syslinux-dont-build-dos-windows-targets.patch
# Fix FHS manpage path
sed 's|/usr/man|/usr/share/man|g' -i mk/syslinux.mk
make installer
make -C utils
make -C com32
}
package() {
cd "$srcdir"/$pkgname-${pkgver}
make INSTALLROOT="$pkgdir" SBINDIR=/usr/bin AUXDIR=/usr/lib/syslinux install
# Install the default configuration
install -D -m644 "$srcdir"/syslinux.cfg "$pkgdir"/boot/syslinux/syslinux.cfg
# Install Parabola splash
install -D -m644 "$srcdir"/splash.png "$pkgdir"/boot/syslinux/splash.png
# Install the installation and update script
# This script is maintained at git://gist.github.com/772138.git
install -D -m755 "$srcdir"/syslinux-install_update "$pkgdir"/usr/bin/syslinux-install_update
}
|
