blob: 64959327cb6a1dc3838d1ee24c433b6364908b3f (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
|
# $Id: PKGBUILD 277244 2016-09-28 12:12:15Z jgc $
# Maintainer (Arch): Ionut Biru <ibiru@archlinux.org>
# Maintainer: André Silva <emulatorman@parabola.nu>
pkgname=empathy
pkgver=3.12.12+35+g8311b76
pkgrel=1.nonprism1
pkgdesc="A GNOME instant messaging client using the Telepathy framework, without geoclue2 support"
url="https://wiki.gnome.org/Apps/Empathy"
arch=(i686 x86_64)
license=(GPL2)
depends=(clutter-gst clutter-gtk folks gcr iso-codes libcanberra libpulse webkitgtk
telepathy-farstream telepathy-glib telepathy-logger telepathy-mission-control
geocode-glib cheese libchamplain libgudev)
makedepends=(intltool itstool docbook-xsl python python2 gnome-common git)
optdepends=('telepathy-gabble: XMPP/Jabber support'
'telepathy-idle: IRC support'
'telepathy-salut: Link-local XMPP support'
'telepathy-rakia: SIP support'
'telepathy-haze: libpurple support')
options=(!makeflags)
groups=(gnome)
_commit=8311b765895d092c178ba81a36dd3956503ef351 # master
source=("git://git.gnome.org/empathy#commit=$_commit")
sha256sums=('SKIP')
pkgver() {
cd $pkgname
git describe --tags | sed 's/^EMPATHY_//;s/_/./g;s/-/+/g'
}
prepare() {
cd $pkgname
NOCONFIGURE=1 ./autogen.sh
}
build() {
cd $pkgname
PYTHON=/usr/bin/python2 ./configure --prefix=/usr \
--sysconfdir=/etc \
--libexecdir=/usr/lib/empathy \
--disable-static \
--enable-location=no
sed -i -e 's/ -shared / -Wl,-O1,--as-needed\0/g' libtool
make
}
package() {
cd $pkgname
make DESTDIR="$pkgdir" install
}
|
