blob: 6e31e3700d17d26f01683ae35af5417e51ee6348 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
|
# Maintainer (Manjaro): artoo <artoo@manjaro.org>
# Contributor (Manjaro): williamh <williamh@gentoo.org>
# Maintainer: Omar Vega Ramos <ovruni@gnu.org.pe>
_url="https://github.com/OpenRC/openrc/archive"
pkgname=openrc
pkgver=0.20.4
pkgrel=1.1
pkgdesc="Gentoo's universal init system"
arch=('i686' 'x86_64' 'armv7h')
url="http://www.gentoo.org/proj/en/base/openrc/"
license=('BSD2')
depends=('psmisc' 'sysvinit')
optdepends=('netifrc: Network Interface Management Scripts'
'networkmanager-openrc: NetworkManager'
'connman-openrc: connman')
conflicts=('systemd-sysvcompat' 'openrc-core')
replaces=('openrc-core')
install=${pkgname}.install
backup=('etc/rc.conf'
'etc/conf.d/consolefont'
'etc/conf.d/keymaps'
'etc/conf.d/hostname'
'etc/conf.d/modules'
'etc/conf.d/hwclock'
'etc/inittab')
source=("${pkgname}-${pkgver}.tar.gz::${_url}/${pkgver}.tar.gz"
"${pkgname}.logrotate"
'use-optional-modules-load-d.patch')
sha256sums=('162018f2cba6d8df74daeca40522ce716370d67f19b8592d4beaa2df5435cee3'
'0b44210db9770588bd491cd6c0ac9412d99124c6be4c9d3f7d31ec8746072f5c'
'54e0cfb59b83ad42ec85486b99b7fed52ccbc8f98f0f113668eacf48a24a2d03')
_args=(BRANDING="Parabola")
_args+=(SYSCONFDIR=/etc)
_args+=(PREFIX=/usr)
_args+=(SBINDIR=/usr/bin)
_args+=(LIBEXECDIR=/usr/lib/rc)
_args+=(MKSELINUX=no)
_args+=(MKPAM=pam)
_args+=(MKTERMCAP=ncurses)
_args+=(MKNET=no)
prepare(){
cd "${srcdir}/${pkgname}-${pkgver}"
sed -e "s|/sbin|/usr/bin|g" -i support/sysvinit/inittab
sed -i 's:0444:0644:' mk/sys.mk
patch -Np1 -i ${srcdir}/use-optional-modules-load-d.patch
}
build(){
cd "${srcdir}/${pkgname}-${pkgver}"
make "${_args[@]}"
}
package() {
cd "${srcdir}/${pkgname}-${pkgver}"
make DESTDIR="${pkgdir}" "${_args[@]}" install
install -m644 "${srcdir}/${pkgname}-${pkgver}/support/sysvinit/inittab" "${pkgdir}/etc/inittab"
install -Dm644 "${srcdir}/${pkgname}.logrotate" "${pkgdir}/etc/logrotate.d/${pkgname}"
sed -e 's/#unicode="NO"/unicode="YES"/' \
-e 's/#rc_logger="YES"/rc_logger="YES"/' \
-i "${pkgdir}/etc/rc.conf"
install -d ${pkgdir}/usr/lib/rc/cache
install -Dm644 ${srcdir}//${pkgname}-${pkgver}/LICENSE "$pkgdir/usr/share/licenses/${pkgname}/LICENSE"
}
|
