blob: 8b5779bdc21fd6512f17c9658a455b51cbaba7b0 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
|
# Maintainer (AUR): Michael Witten
#
# Derived from perl-crypt-blowfish:
# Contributor (Arch): Sergej Pupykin <pupykin.s+arch@gmail.com>
# Contributor (Arch): Charles Mauch <cmauch@gmail.com>
#
# Contributor (Arch): Pedro Alejandro López-Valencia <palopezv@gmail.com>
pkgname=perl-crypt-dh
pkgver=0.07
pkgrel=3
pkgdesc='Perl/CPAN Module Crypt::DH: Diffie-Hellman key exchange system'
_cpan_name=Crypt-DH-$pkgver
url=http://search.cpan.org/~mithaldu/$_cpan_name/lib/Crypt/DH.pm
license=(GPL PerlArtistic)
source=("http://search.cpan.org/CPAN/authors/id/M/MI/MITHALDU/$_cpan_name.tar.gz")
md5sums=(5494c91420bf77de4af808fcafb6c3ce)
arch=(any)
makedepends=(make)
depends=(perl perl-math-bigint-gmp)
build()
{
cd "$srcdir/$_cpan_name"
PERL_MM_USE_DEFAULT=1 perl Makefile.PL INSTALLDIRS=vendor
make
}
check()
{
cd "$srcdir/$_cpan_name"
make test
}
package()
{
cd "$srcdir/$_cpan_name"
make pure_install DESTDIR="$pkgdir"
cd "$pkgdir"
find . -name '.packlist' -delete
find . -name '*.pod' -delete
}
|
