blob: 1791e31a8578edc978545113f0407bc8d3012a05 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
|
# Maintainer : Martin Wimpress <code@flexion.org>
# Contributor: Sauyon Lee <sauyonl@sauyon.com>
# Contributor: Kevin MacMartin <prurigro@gmail.com>
pkgname=syncthing
pkgver=0.8.13
pkgrel=1
pkgdesc="Open Source Continuous Replication / Cluster Synchronization Thing"
url="http://syncthing.net/"
license=('MIT')
arch=('i686' 'x86_64' 'mips64el')
depends=('glibc')
makedepends=('git' 'go' 'godep' 'inetutils')
source=("${pkgname}::git+https://github.com/calmh/syncthing.git#tag=v${pkgver}"
"syncthing@.service"
"syncthing.1")
sha1sums=('SKIP'
'204cad3823306c793a14a17a23220e26199160d4'
'cabf3bf78457ce17057ae39fe3b0009a4aa446c4')
install=${pkgname}.install
prepare() {
cd "${srcdir}"
mkdir -p "src/github.com/calmh"
mv "${pkgname}" "src/github.com/calmh/${pkgname}"
}
build() {
export GOPATH="${srcdir}"
cd "${srcdir}/src/github.com/calmh/${pkgname}"
./build.sh
}
check() {
export GOPATH="${srcdir}"
cd "${srcdir}/src/github.com/calmh/${pkgname}"
./build.sh test
}
package() {
cd "${srcdir}/src/github.com/calmh/${pkgname}"
install -D -m 755 syncthing "${pkgdir}/usr/bin/syncthing"
install -D -m 644 LICENSE "${pkgdir}/usr/share/licenses/${pkgname}/LICENSE"
install -D -m 644 README.md "${pkgdir}/usr/share/doc/${pkgname}/README.md"
install -D -m 644 "${srcdir}/${pkgname}@.service" "${pkgdir}/usr/lib/systemd/system/${pkgname}@.service"
install -D -m 644 "${srcdir}/${pkgname}.1" "${pkgdir}/usr/share/man/man1/${pkgname}.1"
}
|
