Tue Aug 13 01:31:08 PDT 2013

1 files changed, 101 insertions, 0 deletions

diff --git a/community/avr-gcc/PKGBUILD b/community/avr-gcc/PKGBUILD
new file mode 100644
index 000000000..3bcecdca4
--- /dev/null
+++ b/community/avr-gcc/PKGBUILD
@@ -0,0 +1,101 @@
+# $Id: PKGBUILD 88836 2013-04-23 14:57:29Z schuay $
+# Maintainer: schuay <jakob.gruber@gmail.com>
+# Contributor: Brad Fanella <bradfanella@archlinux.us>
+# Contributor: Corrado Primier <bardo@aur.archlinux.org>
+# Contributor: danst0 <danst0@west.de>
+
+# Build order: avr-binutils -> avr-gcc -> avr-libc
+
+pkgname=avr-gcc
+_pkgname=gcc
+pkgver=4.8.0
+pkgrel=2
+pkgdesc="The GNU AVR Compiler Collection"
+arch=('i686' 'x86_64')
+license=('GPL' 'LGPL' 'FDL' 'custom')
+url="http://gcc.gnu.org/"
+depends=('avr-binutils>=2.23' 'cloog' 'ppl' 'gcc-libs>=4.8.0' 'libmpc')
+optdepends=('avr-libc: Standard C library for Atmel AVR development')
+provides=("gcc-avr=$pkgver")
+replaces=('gcc-avr')
+options=('!libtool' '!emptydirs' '!strip')
+source=(http://ftp.gnu.org/gnu/gcc/${_pkgname}-${pkgver}/gcc-${pkgver}.tar.bz2)
+
+_basedir=${_pkgname}-${pkgver}
+
+build() {
+    # default CFLAGS lead to issues later on when configure 
+    # calls avr-gcc with -march set.
+    export CFLAGS="-O2 -pipe"
+    export CXXFLAGS="-O2 -pipe"
+
+    cd ${srcdir}/${_basedir} 
+
+    # Do not install libiberty
+    sed -i 's/install_to_$(INSTALL_DEST) //' libiberty/Makefile.in
+
+    # https://bugs.archlinux.org/task/34629
+    sed -i "/ac_cpp=/s/\$CPPFLAGS/\$CPPFLAGS -O2/" libiberty/configure
+    sed -i "/ac_cpp=/s/\$CPPFLAGS/\$CPPFLAGS -O2/" gcc/configure
+
+    echo ${pkgver} > gcc/BASE-VER
+
+    cd ${srcdir}
+    mkdir gcc-build && cd gcc-build
+
+    # --disable-linker-build-id: https://bugs.archlinux.org/task/34902
+
+    ${srcdir}/${_basedir}/configure \
+                --disable-cloog-version-check \
+                --disable-install-libiberty \
+                --disable-libssp \
+                --disable-libstdcxx-pch \
+                --disable-libunwind-exceptions \
+                --disable-linker-build-id \
+                --disable-nls \
+                --disable-werror \
+                --enable-__cxa_atexit \
+                --enable-checking=release \
+                --enable-clocale=gnu \
+                --enable-cloog-backend=isl \
+                --enable-gnu-unique-object \
+                --enable-gold \
+                --enable-languages=c,c++ \
+                --enable-ld=default \
+                --enable-lto \
+                --enable-plugin \
+                --enable-shared \
+                --infodir=/usr/share/info \
+                --libdir=/usr/lib \
+                --libexecdir=/usr/lib \
+                --mandir=/usr/share/man \
+                --prefix=/usr \
+                --target=avr \
+                --with-as=/usr/bin/avr-as \
+                --with-gnu-as \
+                --with-gnu-ld \
+                --with-ld=/usr/bin/avr-ld \
+                --with-plugin-ld=ld.gold \
+                --with-system-zlib
+
+    make
+}
+
+package() {
+    cd ${srcdir}/gcc-build
+
+    make -j1 DESTDIR=${pkgdir} install
+
+    # Strip debug symbols from libraries; without this, the package size balloons to ~500MB.
+    find ${pkgdir}/usr/lib -type f -name "*.a" \
+        -exec /usr/bin/avr-strip --strip-debug '{}' \;
+
+    # Install Runtime Library Exception
+    install -Dm644 ${srcdir}/${_basedir}/COPYING.RUNTIME \
+        ${pkgdir}/usr/share/licenses/${pkgname}/RUNTIME.LIBRARY.EXCEPTION
+
+    rm -rf ${pkgdir}/usr/share/man/man7
+    rm -rf ${pkgdir}/usr/share/info
+}
+
+md5sums=('e6040024eb9e761c3bea348d1fa5abb0')