Fri Dec 27 23:54:04 UTC 2013

2 files changed, 98 insertions, 0 deletions

diff --git a/community/mingw-w64-gcc/PKGBUILD b/community/mingw-w64-gcc/PKGBUILD
new file mode 100644
index 000000000..999fc9584
--- /dev/null
+++ b/community/mingw-w64-gcc/PKGBUILD
@@ -0,0 +1,74 @@
+# $Id: PKGBUILD 101210 2013-11-19 19:03:58Z spupykin $
+# Maintainer: Sergej Pupykin <pupykin.s+arch@gmail.com>
+# Maintainer: rubenvb vanboxem <dottie> ruben <attie> gmail <dottie> com
+
+_targets="i686-w64-mingw32 x86_64-w64-mingw32"
+
+pkgname=mingw-w64-gcc
+pkgver=4.8.2
+pkgrel=4
+pkgdesc="Cross GCC for the MinGW-w64 cross-compiler"
+arch=('i686' 'x86_64')
+url="http://gcc.gnu.org"
+license=('GPL' 'LGPL' 'FDL' 'custom')
+groups=('mingw-w64-toolchain' 'mingw-w64')
+depends=('zlib' 'libmpc' 'ppl' 'cloog' 'mingw-w64-crt' 'mingw-w64-binutils' 'mingw-w64-winpthreads' 'mingw-w64-headers' 'mingw-w64-headers-bootstrap')
+makedepends=("gcc-ada=${pkgver}" 'mingw-w64-gcc-base')
+#checkdepends=('dejagnu') # Windows executables could run on Arch through bin_mft and Wine
+optdepends=()
+provides=('mingw-w64-gcc-base')
+conflicts=('mingw-w64-gcc-base')
+replaces=()
+backup=()
+options=('!strip' 'staticlibs' '!emptydirs' '!buildflags')
+source=("ftp://gcc.gnu.org/pub/gcc/releases/gcc-${pkgver}/gcc-${pkgver}.tar.bz2"
+        'gcc-make-xmmintrin-header-cplusplus-compatible.patch')
+md5sums=('a3d7d63b9cb6b6ea049469a0c4a43c9d'
+         'da6c9ba6baebe1286f3219d4181cdbb8')
+
+prepare() {
+  cd ${srcdir}/gcc-${pkgver}
+
+  #do not install libiberty
+  sed -i 's/install_to_$(INSTALL_DEST) //' libiberty/Makefile.in
+  # hack! - some configure tests for header files using "$CPP $CPPFLAGS"
+  sed -i "/ac_cpp=/s/\$CPPFLAGS/\$CPPFLAGS -O2/" {libiberty,gcc}/configure
+
+  # The file xmmintrin.h doesn't contain an extern "C" part
+  # This conflicts with mingw-w64 intrin.h and results in build
+  # failure like this one in mingw-w64-qt5-qtbase:
+  # /usr/lib/gcc/i686-w64-mingw32/4.8.0/include/xmmintrin.h:997:1: error: previous declaration of 'int _m_pextrw(__m64, int)' with 'C++' linkage
+  # /usr/i686-w64-mingw32/include/intrin.h:561:28: error: conflicts with new declaration with 'C' linkage
+  patch -p0 -i ${srcdir}/gcc-make-xmmintrin-header-cplusplus-compatible.patch
+}
+
+build() {
+  for _target in ${_targets}; do
+    mkdir -p ${srcdir}/gcc-build-${_target} && cd ${srcdir}/gcc-build-${_target}
+
+    ${srcdir}/gcc-${pkgver}/configure --prefix=/usr \
+        --target=${_target} \
+        --enable-languages=c,lto,c++,objc,obj-c++,fortran,ada \
+        --enable-shared --enable-static \
+        --enable-threads=posix --enable-fully-dynamic-string --enable-libstdcxx-time=yes \
+        --with-system-zlib --enable-cloog-backend=isl \
+        --disable-cloog-version-check --disable-isl-version-check \
+        --enable-lto --disable-dw2-exceptions --enable-libgomp \
+        --disable-multilib --enable-checking=release
+    make all
+  done
+}
+
+package() {
+  for _target in ${_targets}; do
+    cd ${srcdir}/gcc-build-${_target}
+    make DESTDIR=${pkgdir} install
+    ${_target}-strip ${pkgdir}/usr/${_target}/lib/*.dll
+    strip ${pkgdir}/usr/bin/${_target}-*
+    strip ${pkgdir}/usr/libexec/gcc/${_target}/${pkgver}/{cc1*,collect2,gnat1,f951,lto*}
+    ln -s ${_target}-gcc $pkgdir/usr/bin/${_target}-cc
+  done
+  strip ${pkgdir}/usr/bin/*
+  # remove unnecessary files
+  rm -r ${pkgdir}/usr/share
+}
diff --git a/community/mingw-w64-gcc/gcc-make-xmmintrin-header-cplusplus-compatible.patch b/community/mingw-w64-gcc/gcc-make-xmmintrin-header-cplusplus-compatible.patch
new file mode 100644
index 000000000..c5ca43209
--- /dev/null
+++ b/community/mingw-w64-gcc/gcc-make-xmmintrin-header-cplusplus-compatible.patch
@@ -0,0 +1,24 @@
+--- gcc/config/i386/xmmintrin.h.orig	2013-01-18 14:57:27.762645582 +0100
++++ gcc/config/i386/xmmintrin.h	2013-01-18 14:58:27.604561940 +0100
+@@ -37,6 +37,10 @@
+ /* Get _mm_malloc () and _mm_free ().  */
+ #include <mm_malloc.h>
+ 
++#ifdef __cplusplus
++extern "C" {
++#endif
++
+ /* The Intel API is flexible enough that we must allow aliasing with other
+    vector types, and their scalar components.  */
+ typedef float __m128 __attribute__ ((__vector_size__ (16), __may_alias__));
+@@ -1241,6 +1245,10 @@
+   (row3) = __builtin_ia32_movhlps (__t3, __t2);				\
+ } while (0)
+ 
++#ifdef __cplusplus
++}
++#endif
++
+ /* For backward source compatibility.  */
+ #ifdef __SSE2__
+ # include <emmintrin.h>