Sat Dec 29 02:10:20 PST 2012

1 files changed, 64 insertions, 0 deletions

diff --git a/extra/audacious-plugins/PKGBUILD b/extra/audacious-plugins/PKGBUILD
new file mode 100644
index 000000000..f9625a77f
--- /dev/null
+++ b/extra/audacious-plugins/PKGBUILD
@@ -0,0 +1,64 @@
+# $Id: PKGBUILD 173108 2012-12-11 04:47:03Z bisson $
+# Maintainer: Gaetan Bisson <bisson@archlinux.org>
+# Contributor: Alexander Fehr <pizzapunk gmail com>
+# Contributor: William Rea <sillywilly@gmail.com>
+
+pkgname=audacious-plugins
+pkgver=3.3.3
+pkgrel=1
+pkgdesc='Plugins for Audacious'
+url='http://audacious-media-player.org/'
+license=('custom:BSD' 'GPL')
+arch=('i686' 'x86_64')
+
+makedepends=("audacious>=${pkgver}"
+             'oss' 'alsa-lib' 'pulseaudio' 'jack2' 'lame' 'libvorbis' 'flac'
+             'mpg123' 'faad2' 'ffmpeg' 'libmodplug' 'fluidsynth' 'libcdio' 'libsidplay' 'wavpack'
+             'libnotify' 'lirc-utils' 'curl' 'libmtp'
+             'neon' 'libmms' 'libcue')
+
+optdepends=('oss: Open Sound System v4 output'
+            'alsa-lib: Advanced Linux Sound Arch. output'
+            'pulseaudio: PulseAudio output'
+            'jack2: Jack Audio Connection Kit output'
+            'lame: FileWriter MP3 output'
+            'libvorbis: Vorbis input, FileWriter Vorbis output'
+            'flac: FLAC input, FileWriter FLAC output'
+
+            'mpg123: MP3 input'
+            'faad2: AAC input'
+            'ffmpeg: ffaudio input'
+            'libmodplug: modplug input'
+            'fluidsynth: MIDI FluidSynth backend input'
+            'libcdio: CD Digital Audio input'
+            'libsidplay: Commodore 64 audio input'
+            'wavpack: WavPack input'
+
+            'libnotify: libnotify OSD'
+            'lirc-utils: LIRC'
+            'curl: AudioScrobbler Client'
+            'libmtp: Upload to MTP device'
+
+            'neon: neon-based http transport'
+            'libmms: libmms-based mms transport'
+            'libcue: CUE playlist format')
+
+source=("http://distfiles.audacious-media-player.org/${pkgname}-${pkgver}.tar.bz2")
+sha1sums=('c7384a2de6e3305f3c3271bb66344f0cbb9bef0e')
+
+build() {
+	cd "${srcdir}/${pkgname}-${pkgver}"
+
+	./configure \
+		--prefix=/usr \
+		--enable-amidiplug \
+		--disable-adplug \
+
+	make
+}
+
+package() {
+	cd "${srcdir}/${pkgname}-${pkgver}"
+	make DESTDIR="${pkgdir}" install
+	install -Dm644 COPYING "${pkgdir}/usr/share/licenses/${pkgname}/LICENSE"
+}