Tue Apr 5 14:26:38 UTC 2011

2 files changed, 109 insertions, 0 deletions

diff --git a/extra/kdeaccessibility/PKGBUILD b/extra/kdeaccessibility/PKGBUILD
new file mode 100644
index 000000000..deae74e5c
--- /dev/null
+++ b/extra/kdeaccessibility/PKGBUILD
@@ -0,0 +1,98 @@
+# $Id: PKGBUILD 111776 2011-02-28 23:54:09Z andrea $
+# Maintainer: Andrea Scarpino <andrea@archlinux.org>
+# Contributor: Pierre Schmitz <pierre@archlinux.de>
+
+pkgbase=kdeaccessibility
+pkgname=('kdeaccessibility-colorschemes'
+         'kdeaccessibility-iconthemes'
+         'kdeaccessibility-jovie'
+         'kdeaccessibility-kaccessible'
+         'kdeaccessibility-kmag'
+         'kdeaccessibility-kmousetool'
+         'kdeaccessibility-kmouth')
+pkgver=4.6.1
+pkgrel=1
+arch=('i686' 'x86_64')
+url='http://accessibility.kde.org'
+license=('GPL' 'FDL')
+groups=('kde' 'kdeaccessibility')
+makedepends=('pkgconfig' 'cmake' 'automoc4' 'kdebase-runtime'
+        'speech-dispatcher' 'docbook-xsl')
+source=("http://download.kde.org/stable/${pkgver}/src/${pkgbase}-${pkgver}.tar.bz2")
+sha1sums=('820c3d85b01e0714826a0e00c779d4ca84ddf093')
+
+build() {
+	cd ${srcdir}
+	mkdir build
+	cd build
+	cmake ../${pkgbase}-${pkgver} \
+		-DCMAKE_BUILD_TYPE=Release \
+		-DCMAKE_SKIP_RPATH=ON \
+		-DCMAKE_INSTALL_PREFIX=/usr \
+        -DWITH_Opentts=OFF
+	make
+}
+
+package_kdeaccessibility-colorschemes() {
+	pkgdesc='KDE Accessibility color schemes'
+	cd $srcdir/build/ColorSchemes
+	make DESTDIR=$pkgdir install
+}
+
+package_kdeaccessibility-iconthemes() {
+	pkgdesc='KDE Accessibility icon themes'
+	cd $srcdir/build/IconThemes
+	make DESTDIR=$pkgdir install
+}
+
+package_kdeaccessibility-jovie() {
+	pkgdesc='A text to speech application'
+	depends=('kdebase-runtime' 'speech-dispatcher')
+    replaces=('kdeaccessibility-kttsd')
+	install='kdeaccessibility.install'
+	cd $srcdir/build/jovie
+	make DESTDIR=$pkgdir install
+	cd $srcdir/build/doc/jovie
+	make DESTDIR=$pkgdir install
+}
+
+package_kdeaccessibility-kaccessible() {
+    pkgdesc='Provides accessibility services like focus tracking and a screenreader'
+    depends=('kdebase-runtime' 'speech-dispatcher')
+	install='kdeaccessibility.install'
+    cd $srcdir/build/kaccessible
+    make DESTDIR=$pkgdir install
+}
+
+package_kdeaccessibility-kmag() {
+	pkgdesc='Screen Magnifier'
+	depends=('kdebase-runtime')
+	url="http://kde.org/applications/utilities/kmag/"
+	install='kdeaccessibility.install'
+	cd $srcdir/build/kmag
+	make DESTDIR=$pkgdir install
+	cd $srcdir/build/doc/kmag
+	make DESTDIR=$pkgdir install
+}
+
+package_kdeaccessibility-kmousetool() {
+	pkgdesc='Clicks the mouse for you, reducing the effects of RSI'
+	depends=('kdebase-runtime')
+	url="http://kde.org/applications/utilities/kmousetool/"
+	install='kdeaccessibility.install'
+	cd $srcdir/build/kmousetool
+	make DESTDIR=$pkgdir install
+	cd $srcdir/build/doc/kmousetool
+	make DESTDIR=$pkgdir install
+}
+
+package_kdeaccessibility-kmouth() {
+	pkgdesc='Speech Synthesizer Frontend'
+	depends=('kdebase-runtime')
+	url="http://kde.org/applications/utilities/kmouth/"
+	install='kdeaccessibility.install'
+	cd $srcdir/build/kmouth
+	make DESTDIR=$pkgdir install
+	cd $srcdir/build/doc/kmouth
+	make DESTDIR=$pkgdir install
+}
diff --git a/extra/kdeaccessibility/kdeaccessibility.install b/extra/kdeaccessibility/kdeaccessibility.install
new file mode 100644
index 000000000..e70c054ec
--- /dev/null
+++ b/extra/kdeaccessibility/kdeaccessibility.install
@@ -0,0 +1,11 @@
+post_install() {
+	xdg-icon-resource forceupdate --theme hicolor &> /dev/null
+}
+
+post_upgrade() {
+	post_install
+}
+
+post_remove() {
+	post_install
+}