Tue Aug 21 00:02:33 UTC 2012

3 files changed, 165 insertions, 0 deletions

diff --git a/libre/doublecmd-libre/PKGBUILD b/libre/doublecmd-libre/PKGBUILD
new file mode 100644
index 000000000..5eee8985c
--- /dev/null
+++ b/libre/doublecmd-libre/PKGBUILD
@@ -0,0 +1,62 @@
+# $Id$
+# Maintainer: BlackIkeEagle <ike DOT devolder AT gmail DOT com>
+# Contributor: (sirocco AT ngs.ru)
+
+_pkgbase=doublecmd
+pkgbase=doublecmd-libre
+pkgname=('doublecmd-gtk2-libre' 'doublecmd-qt-libre')
+pkgver=0.5.4
+_helpver=0.5.1
+pkgrel=2.1
+url="http://doublecmd.sourceforge.net/"
+arch=('i686' 'x86_64')
+license=('GPL')
+install="$_pkgbase.install"
+makedepends=('lazarus' 'qt4pas' 'gtk2')
+optdepends=('lua: scripting' 'p7zip: support for 7zip archives')
+source=("http://downloads.sourceforge.net/project/$_pkgbase/Double%20Commander%20Source/$_pkgbase-$pkgver-src.tar.gz"
+	"http://downloads.sourceforge.net/project/$_pkgbase/Double%20Commander%20Source/$_pkgbase-help-$_helpver-src.tar.gz"
+)
+sha256sums=('480b83279adeba007ad5c54f455733fae3d9c9ee61762e6b5a63e2e67b1cd7b7'
+            'd9f518e05e089b71aaa31c7d4af8177e77594a02be2c316e85e061e63b4c03e5')
+
+build() {
+	cp -a $_pkgbase-$pkgver $_pkgbase-gtk
+	cp -a $_pkgbase-$pkgver $_pkgbase-qt
+
+	cd "$srcdir/$_pkgbase-gtk"
+	./build.sh beta gtk2
+
+	cd "$srcdir/$_pkgbase-qt"
+	./build.sh beta qt
+}
+
+package_doublecmd-gtk2-libre() {
+	pkgdesc="twin-panel (commander-style) file manager (GTK)"
+	depends=('gtk2')
+	conflicts=('doublecmd-gtk2')
+	replaces=('doublecmd-gtk2')
+	provides=("doublecmd-gtk2=${pkgver}" 'doublecmd')
+	cd "$srcdir/$_pkgbase-gtk"
+	sed -e 's/LIB_SUFFIX=.*/LIB_SUFFIX=/g' -i ./install/linux/install.sh
+	./install/linux/install.sh --install-prefix="$pkgdir"
+
+	# install doc
+	cd "$srcdir/$_pkgbase-help-$_helpver"
+	cp -a * "$pkgdir/usr/share/$_pkgbase/doc/"
+}
+
+package_doublecmd-qt-libre() {
+	pkgdesc="twin-panel (commander-style) file manager (QT)"
+	depends=('qt4pas')
+	conflicts=('doublecmd-qt')
+	replaces=('doublecmd-qt')
+	provides=("doublecmd-qt=${pkgver}" 'doublecmd')
+	cd "$srcdir/$_pkgbase-qt"
+	sed -e 's/LIB_SUFFIX=.*/LIB_SUFFIX=/g' -i ./install/linux/install.sh
+	./install/linux/install.sh --install-prefix="$pkgdir"
+
+	# install doc
+	cd "$srcdir/$_pkgbase-help-$_helpver"
+	cp -a * "$pkgdir/usr/share/$_pkgbase/doc/"
+}
diff --git a/libre/doublecmd-libre/doublecmd.install b/libre/doublecmd-libre/doublecmd.install
new file mode 100644
index 000000000..40d56528f
--- /dev/null
+++ b/libre/doublecmd-libre/doublecmd.install
@@ -0,0 +1,34 @@
+update_icons() {
+
+	# Setup Menus
+	if which update-desktop-database
+	then
+		update-desktop-database -q /usr/share/applications
+	fi
+
+	# Setup MIME types
+	if which update-mime-database
+	then
+		update-mime-database /usr/share/mime >/dev/null
+	fi
+
+	# Setup Icons
+	touch -c /usr/share/icons/hicolor
+	if which gtk-update-icon-cache
+	then
+		gtk-update-icon-cache -tq /usr/share/icons/hicolor
+	fi
+
+}
+
+post_install() {
+	update_icons
+}
+
+post_upgrade() {
+	update_icons
+}
+
+post_remove() {
+	update_icons
+}
diff --git a/libre/mc-libre/PKGBUILD b/libre/mc-libre/PKGBUILD
new file mode 100644
index 000000000..3528fba0e
--- /dev/null
+++ b/libre/mc-libre/PKGBUILD
@@ -0,0 +1,69 @@
+# $Id$
+# Contributor: Daniel J Griffiths <ghost1227@archlinux.us>
+# Maintainer: schuay <jakob.gruber@gmail.com>
+
+_pkgname=mc
+pkgname=mc-libre
+pkgver=4.8.4
+pkgrel=1
+pkgdesc="Midnight Commander is a text based filemanager/shell that emulates Norton Commander"
+arch=('i686' 'x86_64')
+url="http://www.ibiblio.org/mc/"
+license=('GPL')
+depends=('e2fsprogs' 'glib2' 'pcre' 'gpm' 'slang')
+makedepends=('libxt' 'libx11')
+optdepends=('p7zip: support for 7zip archives'
+	'mtools: a+ extfs'
+	'cdparanoia: audio extfs'
+	'gawk: hp48+ extfs'
+	'cdrkit: iso9660 extfs'
+	'perl: needed by several extfs scripts'
+	'python-boto: s3+ extfs'
+	'python2-pytz: s3+ extfs'
+	'p7zip: u7z extfs'
+	'arj: uarj extfs'
+	'cabextract: ucab extfs'
+	'ununrar: urar extfs'
+	'zip: uzip extfs')
+conflicts=('mc')
+replaces=('mc')
+provides=("mc=${pkgver}")
+options=('!emptydirs' '!makeflags')
+backup=('etc/mc/edit.indent.rc'
+        'etc/mc/edit.spell.rc'
+        'etc/mc/filehighlight.ini'
+        'etc/mc/mcedit.menu'
+        'etc/mc/mc.ext'
+        'etc/mc/mc.keymap'
+        'etc/mc/mc.menu'
+        'etc/mc/sfs.ini')
+source=("http://www.midnight-commander.org/downloads/${_pkgname}-${pkgver}.tar.bz2")
+
+build() {
+	cd "${srcdir}/${_pkgname}-${pkgver}"
+
+	./configure \
+	    --prefix=/usr --sysconfdir=/etc --mandir=/usr/share/man \
+	    --enable-background --enable-charset --enable-largefile \
+	    --with-edit --with-gpm-mouse --with-mmap --enable-vfs-smb \
+	    --with-screen=slang --with-subshell --with-vfs --with-x \
+	    --without-debug --without-gnome --without-included-gettext \
+	    --libexecdir=/usr/lib
+
+	make
+}
+
+package() {
+	cd "${srcdir}/${_pkgname}-${pkgver}"
+
+	make DESTDIR="${pkgdir}" install
+
+	# Fix FS#15177
+	sed 's|op_has_zipinfo = 0|op_has_zipinfo = 1|' \
+		-i "${pkgdir}/usr/lib/mc/extfs.d/uzip"
+
+	sed 's#/usr/bin/env python#/usr/bin/python2#' \
+		-i "${pkgdir}/usr/lib/mc/extfs.d/s3+"
+}
+
+md5sums=('a8edb8226cb25869f925ecce043faf1e')