Tue Jan 31 23:14:56 UTC 2012

1 files changed, 86 insertions, 0 deletions

diff --git a/multilib-testing/lib32-qt/PKGBUILD b/multilib-testing/lib32-qt/PKGBUILD
new file mode 100644
index 000000000..4cbc5b7a4
--- /dev/null
+++ b/multilib-testing/lib32-qt/PKGBUILD
@@ -0,0 +1,86 @@
+# $Id: PKGBUILD 63340 2012-01-30 19:30:59Z ibiru $
+# Maintainer: Florian Pritz <flo@xssn.at>
+# Contributor: Andrea Scarpino <andrea@archlinux.org>
+# Contributor: Pierre Schmitz <pierre@archlinux.de>
+
+_pkgbasename=qt
+pkgname=lib32-$_pkgbasename
+pkgver=4.8.0
+pkgrel=2
+pkgdesc='A cross-platform application and UI framework (32-bit)'
+arch=('x86_64')
+url='http://qt-project.org/'
+license=('GPL3' 'LGPL')
+depends=(lib32-{fontconfig,sqlite3,alsa-lib,glib2,dbus-core,openssl}
+         lib32-lib{png,tiff,mng,gl,sm,xrandr,xv,xi} $_pkgbasename)
+optdepends=('lib32-libxinerama: Xinerama support'
+            'lib32-libxcursor: Xcursor support'
+            'lib32-libxfixes: Xfixes support')
+makedepends=(cups gcc-multilib lib32-{mesa,libcups,libxfixes,gtk2})
+options=('!libtool')
+_pkgfqn="${_pkgbasename}-everywhere-opensource-src-${pkgver}"
+source=("ftp://get.qt.nokia.com/qt/source/${_pkgfqn}.tar.gz")
+md5sums=('e8a5fdbeba2927c948d9f477a6abe904')
+
+build() {
+  cd $srcdir/$_pkgfqn
+
+  export QT4DIR=$srcdir/$_pkgfqn
+  export LD_LIBRARY_PATH=${QT4DIR}/lib:${LD_LIBRARY_PATH}
+  export PKG_CONFIG_PATH="/usr/lib32/pkgconfig"
+
+  # some of those are likely unnecessary, but I'm too lazy to find and remove them
+  sed -i "/^QMAKE_LINK\s/s|g++|g++ -m32|g" mkspecs/common/g++-base.conf
+  sed -i "s|-O2|${CXXFLAGS} -m32|" mkspecs/common/g++-base.conf
+  sed -i "s|-O2|${CXXFLAGS} -m32|" mkspecs/common/gcc-base.conf
+  sed -i "/^QMAKE_LFLAGS_RPATH/s| -Wl,-rpath,||g" mkspecs/common/gcc-base-unix.conf
+  sed -i "/^QMAKE_LFLAGS\s/s|+=|+= ${LDFLAGS} -m32|g" mkspecs/common/gcc-base.conf
+  sed -i "s|-Wl,-O1|-m32 -Wl,-O1|" mkspecs/common/g++-unix.conf
+  sed -e "s|-O2|$CXXFLAGS -m32|" \
+      -e "/^QMAKE_RPATH/s| -Wl,-rpath,||g" \
+      -e "/^QMAKE_LINK\s/s|g++|g++ -m32|g" \
+      -e "/^QMAKE_LFLAGS\s/s|+=|+= $LDFLAGS|g" \
+      -i mkspecs/common/g++.conf
+
+  ./configure -confirm-license -opensource -v -platform linux-g++-32 \
+    -prefix /usr \
+    -libdir /usr/lib32 \
+    -plugindir /usr/lib32/qt/plugins \
+    -importdir /usr/lib32/qt/imports \
+    -datadir /usr/share/qt \
+    -translationdir /usr/share/qt/translations \
+    -sysconfdir /etc \
+    -system-sqlite \
+    -no-phonon \
+    -no-phonon-backend \
+    -no-webkit \
+    -graphicssystem raster \
+    -openssl-linked \
+    -nomake demos \
+    -nomake examples \
+    -nomake docs \
+    -nomake tools \
+    -optimized-qmake \
+    -no-rpath \
+    -dbus-linked \
+    -reduce-relocations \
+    -no-openvg
+
+  make
+}
+
+package() {
+  cd $srcdir/$_pkgfqn
+  make INSTALL_ROOT=$pkgdir install
+
+  # Fix wrong path in pkgconfig files
+  find ${pkgdir}/usr/lib32/pkgconfig -type f -name '*.pc' \
+    -exec perl -pi -e "s, -L${srcdir}/?\S+,,g" {} \;
+  # Fix wrong path in prl files
+  find ${pkgdir}/usr/lib32 -type f -name '*.prl' \
+    -exec sed -i -e '/^QMAKE_PRL_BUILD_DIR/d;s/\(QMAKE_PRL_LIBS =\).*/\1/' {} \;
+
+  rm -rf "${pkgdir}"/usr/{include,share,bin}
+  mkdir -p "$pkgdir/usr/share/licenses"
+  ln -s $_pkgbasename "$pkgdir/usr/share/licenses/$pkgname"
+}