Thu Nov 24 23:14:53 UTC 2011

4 files changed, 133 insertions, 0 deletions

diff --git a/staging/kdemultimedia/PKGBUILD b/staging/kdemultimedia/PKGBUILD
new file mode 100644
index 000000000..a55ae09ea
--- /dev/null
+++ b/staging/kdemultimedia/PKGBUILD
@@ -0,0 +1,108 @@
+# $Id: PKGBUILD 143183 2011-11-23 08:18:49Z andrea $
+# Maintainer: Andrea Scarpino <andrea@archlinux.org>
+# Contributor: Pierre Schmitz <pierre@archlinux.de>
+
+pkgbase=kdemultimedia
+pkgname=('kdemultimedia-dragonplayer'
+         'kdemultimedia-ffmpegthumbs'
+         'kdemultimedia-juk'
+         'kdemultimedia-kioslave'
+         'kdemultimedia-kmix'
+         'kdemultimedia-kscd'
+         'kdemultimedia-mplayerthumbs')
+pkgver=4.7.80
+pkgrel=1
+arch=('i686' 'x86_64')
+url='http://www.kde.org'
+license=('GPL' 'LGPL' 'FDL')
+groups=('kde' 'kdemultimedia')
+makedepends=('cmake' 'automoc4' 'kdelibs' 'tunepimp' 'ffmpeg' 'mplayer'
+             'pulseaudio' 'libmusicbrainz3')
+source=("http://download.kde.org/unstable/${pkgver}/src/${pkgbase}-${pkgver}.tar.bz2"
+        'mplayerthumbs.config')
+sha1sums=('44b9adf781fcbebe1214fc87b006bf13ddd8b702'
+          'ba016fa2563c14ffcba852c62506b66bfc6ee683')
+
+build() {
+    cd ${srcdir}
+	mkdir build
+	cd build
+	cmake ../${pkgbase}-${pkgver} \
+		-DCMAKE_BUILD_TYPE=Release \
+		-DCMAKE_SKIP_RPATH=ON \
+		-DCMAKE_INSTALL_PREFIX=/usr
+	make
+}
+
+package_kdemultimedia-dragonplayer() {
+	pkgdesc='Video Player'
+	depends=('kdebase-runtime')
+	url="http://kde.org/applications/multimedia/dragonplayer/"
+	install='kdemultimedia-dragonplayer.install'
+	cd $srcdir/build/dragonplayer
+	make DESTDIR=$pkgdir install
+	cd $srcdir/build/doc/dragonplayer
+	make DESTDIR=$pkgdir install
+}
+
+package_kdemultimedia-ffmpegthumbs() {
+	pkgdesc='Video Files (ffmpegthumbs)'
+	depends=('kdebase-runtime' 'ffmpeg')
+	install='kdemultimedia.install'
+	cd $srcdir/build/ffmpegthumbs
+	make DESTDIR=$pkgdir install
+}
+
+package_kdemultimedia-juk() {
+	pkgdesc='Music Player'
+	depends=('kdebase-runtime' 'tunepimp')
+	url="http://kde.org/applications/multimedia/juk"
+	install='kdemultimedia.install'
+	cd $srcdir/build/juk
+	make DESTDIR=$pkgdir install
+	cd $srcdir/build/doc/juk
+	make DESTDIR=$pkgdir install
+}
+
+package_kdemultimedia-kioslave() {
+	pkgdesc='Audio CD Browser'
+	depends=('kdelibs' 'libmusicbrainz3' 'cdparanoia')
+	conflicts=('kdemultimedia-libkcddb' 'kdemultimedia-libkcompactdisc')
+	replaces=('kdemultimedia-libkcddb' 'kdemultimedia-libkcompactdisc')
+	for i in kioslave doc/kioslave libkcddb libkcompactdisc; do
+		cd $srcdir/build/${i}
+		make DESTDIR=$pkgdir install
+	done
+}
+
+package_kdemultimedia-kmix() {
+	pkgdesc='Sound Mixer'
+	depends=('kdebase-runtime')
+	url="http://kde.org/applications/multimedia/kmix"
+	install='kdemultimedia.install'
+	cd $srcdir/build/kmix
+	make DESTDIR=$pkgdir install
+	cd $srcdir/build/doc/kmix
+	make DESTDIR=$pkgdir install
+}
+
+package_kdemultimedia-kscd() {
+	pkgdesc='CD Player'
+	depends=('kdebase-runtime' 'libmusicbrainz3')
+	url="http://kde.org/applications/multimedia/kscd"
+	install='kdemultimedia.install'
+	cd $srcdir/build/kscd
+	make DESTDIR=$pkgdir install
+	cd $srcdir/build/doc/kcontrol/cddbretrieval
+	make DESTDIR=$pkgdir install
+}
+
+package_kdemultimedia-mplayerthumbs() {
+	pkgdesc='Video Files (MPlayerThumbs)'
+	depends=('kdebase-runtime' 'mplayer')
+	replaces=('mplayerthumbs')
+	conflicts=('mplayerthumbs')
+	cd $srcdir/build/mplayerthumbs
+	make DESTDIR=$pkgdir install
+	install -D -m644 $srcdir/mplayerthumbs.config $pkgdir/usr/share/config/mplayerthumbs
+}
diff --git a/staging/kdemultimedia/kdemultimedia-dragonplayer.install b/staging/kdemultimedia/kdemultimedia-dragonplayer.install
new file mode 100644
index 000000000..5495fb1b5
--- /dev/null
+++ b/staging/kdemultimedia/kdemultimedia-dragonplayer.install
@@ -0,0 +1,12 @@
+post_install() {
+    xdg-icon-resource forceupdate --theme hicolor &> /dev/null
+    update-desktop-database -q
+}
+
+post_upgrade() {
+    post_install
+}
+
+post_remove() {
+    post_install
+}
diff --git a/staging/kdemultimedia/kdemultimedia.install b/staging/kdemultimedia/kdemultimedia.install
new file mode 100644
index 000000000..e70c054ec
--- /dev/null
+++ b/staging/kdemultimedia/kdemultimedia.install
@@ -0,0 +1,11 @@
+post_install() {
+	xdg-icon-resource forceupdate --theme hicolor &> /dev/null
+}
+
+post_upgrade() {
+	post_install
+}
+
+post_remove() {
+	post_install
+}
diff --git a/staging/kdemultimedia/mplayerthumbs.config b/staging/kdemultimedia/mplayerthumbs.config
new file mode 100644
index 000000000..761a17953
--- /dev/null
+++ b/staging/kdemultimedia/mplayerthumbs.config
@@ -0,0 +1,2 @@
+[MPlayerThumbsCfg]
+backend=0