1 files changed, 41 insertions, 0 deletions
diff --git a/community-testing/surf/PKGBUILD b/community-testing/surf/PKGBUILD
new file mode 100644
index 000000000..c456f5c45
--- /dev/null
+++ b/community-testing/surf/PKGBUILD
@@ -0,0 +1,41 @@
+# $Id: PKGBUILD 44535 2011-04-08 08:10:39Z lfleischer $
+# Maintainer: Lukas Fleischer <archlinux at cryptocrack dot de>
+# Contributor: Pierre Chapuis <catwell at archlinux dot us>
+# Contributor: Ray Kohler <ataraxia937 at gmail dot com>
+# Contributor: Michael Witten <mfwitten>
+
+pkgname=surf
+pkgver=0.4.1
+pkgrel=2
+pkgdesc="A simple web browser based on WebKit/GTK+."
+arch=('i686' 'x86_64')
+url='http://surf.suckless.org/'
+license=('MIT')
+depends=('libwebkit')
+optdepends=('dmenu: URL-bar'
+            'wget: default download handler')
+makedepends=('pkgconfig')
+install='surf.install'
+source=("http://dl.suckless.org/${pkgname}/${pkgname}-${pkgver}.tar.gz"
+        'config.h')
+md5sums=('28ac7a6d193d25844aa6b1db77fcbafa'
+         'a1d40e130189343a74f83166410f35d7')
+
+build() {
+  cd "${srcdir}/${pkgname}-${pkgver}"
+
+  cp "${srcdir}/config.h" config.h
+
+  sed -i 's/CPPFLAGS =/CPPFLAGS +=/g' config.mk
+  sed -i 's/CFLAGS =/CFLAGS +=/g' config.mk
+  sed -i 's/LDFLAGS =/LDFLAGS +=/g' config.mk
+
+  make
+}
+
+package() {
+  cd "${srcdir}/${pkgname}-${pkgver}"
+
+  make PREFIX=/usr DESTDIR="${pkgdir}" install
+  install -Dm0644 LICENSE "${pkgdir}/usr/share/licenses/${pkgname}/LICENSE"
+}