1 files changed, 44 insertions, 0 deletions
diff --git a/community/haskell-data-default/PKGBUILD b/community/haskell-data-default/PKGBUILD
new file mode 100644
index 000000000..a67fb8d44
--- /dev/null
+++ b/community/haskell-data-default/PKGBUILD
@@ -0,0 +1,44 @@
+# Contributor: Lex Black <autumn-wind at web dot de>
+# Contributor: Don Stewart <dons@galois.com>
+
+pkgname=haskell-data-default
+_hkgname=data-default
+_licensefile=LICENSE
+pkgver=0.5.1
+pkgrel=2
+pkgdesc="A class for types with a default value"
+url="http://hackage.haskell.org/package/${_hkgname}"
+license=('BSD')
+arch=('i686' 'x86_64')
+makedepends=('ghc')
+depends=('haskell-containers' 'haskell-dlist' 'haskell-old-locale')
+options=('strip')
+source=("http://hackage.haskell.org/packages/archive/${_hkgname}/${pkgver}/${_hkgname}-${pkgver}.tar.gz")
+sha256sums=('fb56f34f820379df4881bcccbcb065389200e20778321e2d6e8c92dad94af717')
+install="${pkgname}.install"
+
+build() {
+    cd ${srcdir}/${_hkgname}-${pkgver}
+    
+    runhaskell Setup configure -O -p --enable-split-objs --enable-shared \
+      --prefix=/usr --docdir=/usr/share/doc/${pkgname} --libsubdir=\$compiler/site-local/\$pkgid
+    #runhaskell Setup configure -O ${PKGBUILD_HASKELL_ENABLE_PROFILING:+-p } --enable-split-objs --enable-shared \
+    #    --prefix=/usr --docdir=/usr/share/doc/${pkgname} \
+    #    --libsubdir=\$compiler/site-local/\$pkgid
+    runhaskell Setup build
+    runhaskell Setup haddock
+    runhaskell Setup register --gen-script
+    runhaskell Setup unregister --gen-script
+    sed -i -r -e "s|ghc-pkg.*unregister[^ ]* |&'--force' |" unregister.sh
+}
+
+package() {
+    cd ${srcdir}/${_hkgname}-${pkgver}
+    install -D -m744 register.sh   ${pkgdir}/usr/share/haskell/${pkgname}/register.sh
+    install    -m744 unregister.sh ${pkgdir}/usr/share/haskell/${pkgname}/unregister.sh
+    install -d -m755 ${pkgdir}/usr/share/doc/ghc/html/libraries
+    ln -s /usr/share/doc/${pkgname}/html ${pkgdir}/usr/share/doc/ghc/html/libraries/${_hkgname}
+    runhaskell Setup copy --destdir=${pkgdir}
+    install -D -m644 LICENSE ${pkgdir}/usr/share/licenses/${pkgname}/LICENSE
+    rm -f ${pkgdir}/usr/share/doc/${pkgname}/LICENSE
+}