3 files changed, 236 insertions, 0 deletions
diff --git a/community/mariadb/PKGBUILD b/community/mariadb/PKGBUILD
new file mode 100644
index 000000000..1a7c9c3a5
--- /dev/null
+++ b/community/mariadb/PKGBUILD
@@ -0,0 +1,133 @@
+# $Id: PKGBUILD 71031 2012-05-22 06:04:35Z bpiotrowski $
+# Maintainer: Bartłomiej Piotrowski <nospam@bpiotrowski.pl>
+
+pkgbase=mariadb
+pkgname=('libmariadbclient' 'mariadb-clients' 'mariadb')
+pkgver=5.5.23
+pkgrel=3
+arch=('i686' 'x86_64')
+license=('GPL')
+url="http://mariadb.org/"
+makedepends=('cmake' 'openssl' 'zlib')
+options=('!libtool')
+source=("http://mirror.de.gsnw.de:56431/$pkgbase/$pkgbase-$pkgver/kvm-tarbake-jaunty-x86/$pkgbase-$pkgver.tar.gz"
+        'mysqld')
+md5sums=('7074fa091b3c1489f45a5ddf12cd5e6f'
+         '3bb5a9a96340feb0184bc057ee6e330b')
+
+build() {
+  cd "${srcdir}"
+  mkdir build
+  cd build
+
+  # CFLAGS/CXXFLAGS as suggested upstream
+  CFLAGS="-fPIC ${CFLAGS} -fno-strict-aliasing -DBIG_JOINS=1 -fomit-frame-pointer" \
+  CXXFLAGS="-fPIC ${CXXFLAGS} -fno-strict-aliasing -DBIG_JOINS=1 -felide-constructors -fno-rtti" \
+
+  cmake ../${pkgbase}-${pkgver} \
+    -DCMAKE_BUILD_TYPE=Release \
+    -DCMAKE_INSTALL_PREFIX=/usr \
+    -DSYSCONFDIR=/etc/mysql \
+    -DMYSQL_DATADIR=/var/lib/mysql \
+    -DMYSQL_UNIX_ADDR=/var/run/mysqld/mysqld.sock \
+    -DDEFAULT_CHARSET=utf8 \
+    -DDEFAULT_COLLATION=utf8_general_ci \
+    -DENABLED_LOCAL_INFILE=ON \
+    -DINSTALL_INFODIR=share/mysql/docs \
+    -DINSTALL_MANDIR=share/man \
+    -DINSTALL_PLUGINDIR=/usr/lib/mysql/plugin \
+    -DINSTALL_SCRIPTDIR=bin \
+    -DINSTALL_INCLUDEDIR=include/mysql \
+    -DINSTALL_DOCREADMEDIR=share/mysql \
+    -DINSTALL_SUPPORTFILESDIR=share/mysql \
+    -DINSTALL_MYSQLSHAREDIR=share/mysql \
+    -DINSTALL_DOCDIR=share/mysql/docs \
+    -DINSTALL_SHAREDIR=share/mysql \
+    -DWITH_READLINE=ON \
+    -DWITH_ZLIB=system \
+    -DWITH_SSL=system \
+    -DWITH_LIBWRAP=OFF \
+    -DWITH_MYSQLD_LDFLAGS="${LDFLAGS}" \
+    -DWITH_EXTRA_CHARSETS=complex \
+    -DWITH_EMBEDDED_SERVER=ON \
+    -DWITH_INNOBASE_STORAGE_ENGINE=1 \
+    -DWITH_PARTITION_STORAGE_ENGINE=1 \
+    -DWITH_PBXT_STORAGE_ENGINE=1 \
+    -DWITHOUT_EXAMPLE_STORAGE_ENGINE=1 \
+    -DWITHOUT_ARCHIVE_STORAGE_ENGINE=1 \
+    -DWITHOUT_BLACKHOLE_STORAGE_ENGINE=1 \
+    -DWITHOUT_FEDERATED_STORAGE_ENGINE=1
+
+  make
+}
+
+package_libmariadbclient(){
+  pkgdesc="MariaDB client libraries"
+  depends=('openssl')
+  conflicts=('libmysqlclient')
+  provides=("libmysqlclient=${pkgver}")
+  
+  cd "${srcdir}"/build
+  for dir in include libmysql libmysqld libservices; do
+    make -C ${dir} DESTDIR="${pkgdir}" install
+  done
+
+  install -d "${pkgdir}"/usr/bin
+  install -m755 scripts/mysql_config "${pkgdir}"/usr/bin/
+  install -d "${pkgdir}"/usr/share/man/man1
+  for man in mysql_config mysql_client_test_embedded mysqltest_embedded; do
+    install -m644 "${srcdir}"/${pkgbase}-${pkgver}/man/$man.1 "${pkgdir}"/usr/share/man/man1/$man.1
+  done
+}
+
+package_mariadb-clients() {
+  pkgdesc="MariaDB client tools"
+  depends=('libmariadbclient')
+  conflicts=('mysql-clients')
+  provides=("mysql-clients=${pkgver}")
+  
+  cd "${srcdir}"/build
+  make -C client DESTDIR="${pkgdir}" install
+
+  # install man pages
+  install -d "${pkgdir}"/usr/share/man/man1
+  for man in mysql mysqladmin mysqlcheck mysqldump mysqlimport mysqlshow mysqlslap; do
+    install -m644 "${srcdir}"/${pkgbase}-${pkgver}/man/$man.1 "${pkgdir}"/usr/share/man/man1/$man.1
+  done
+
+  # provided by mariadb
+  rm "${pkgdir}"/usr/bin/{mysql_{plugin,upgrade},mysqlbinlog,mysqltest}
+}
+
+package_mariadb() {
+  pkgdesc="A fast SQL database server, drop-in replacement for MySQL"
+  backup=('etc/mysql/my.cnf')
+  install=mariadb.install
+  depends=('mariadb-clients')
+  conflicts=('mysql')
+  provides=("mysql=${pkgver}")
+  optdepends=('perl-dbi' 'perl-dbd-mysql')
+  options=('emptydirs')
+
+  cd "${srcdir}"/build
+  make DESTDIR="${pkgdir}" install
+
+  install -Dm644 "${pkgdir}"/usr/share/mysql/my-medium.cnf "${pkgdir}"/etc/mysql/my.cnf
+  install -Dm755 "${srcdir}"/mysqld "${pkgdir}"/etc/rc.d/mysqld
+
+  # provided by libmariadbclient
+  rm "${pkgdir}"/usr/bin/{mysql_config,mysql_client_test_embedded,mysqltest_embedded}
+  rm "${pkgdir}"/usr/lib/libmysql*
+  rm -r "${pkgdir}"/usr/include/
+  rm "${pkgdir}"/usr/share/man/man1/{mysql_config,mysql_client_test_embedded,mysqltest_embedded}.1
+  
+  # provided by mariadb-clients
+  rm "${pkgdir}"/usr/bin/{mysql,mysqladmin,mysqlcheck,mysqldump,mysqlimport,mysqlshow,mysqlslap}
+  rm "${pkgdir}"/usr/share/man/man1/{mysql,mysqladmin,mysqlcheck,mysqldump,mysqlimport,mysqlshow,mysqlslap}.1
+
+  # not needed
+  rm -r "${pkgdir}"/usr/{data,mysql-test,sql-bench}
+  rm "${pkgdir}"/usr/share/man/man1/mysql-test-run.pl.1
+
+  install -dm700 "${pkgdir}"/var/lib/mysql
+}
diff --git a/community/mariadb/mariadb.install b/community/mariadb/mariadb.install
new file mode 100644
index 000000000..9a4479215
--- /dev/null
+++ b/community/mariadb/mariadb.install
@@ -0,0 +1,26 @@
+post_install(){
+  groupadd -g 89 mysql &>/dev/null
+  useradd -u 89 -g mysql -d /var/lib/mysql -s /bin/false mysql &>/dev/null
+  usr/bin/mysql_install_db --user=mysql --basedir=/usr
+  chown -R mysql:mysql var/lib/mysql &>/dev/null
+}
+
+post_upgrade(){
+  getent group mysql >/dev/null 2>&1 || groupadd -g 89 mysql &>/dev/null
+  getent passwd mysql >/dev/null 2>&1 || useradd -u 89 -g mysql -d /var/lib/mysql -s /bin/false mysql &>/dev/null
+
+  if [ "$(vercmp $2 5.5)" -lt 0 ]; then
+    echo " >> "
+    echo " >> Major version update. Consider restart the service, and then running mysql_upgrade after it."
+    echo " >> "
+  fi
+}
+
+post_remove(){
+  if getent passwd mysql >/dev/null 2>&1; then
+    userdel mysql
+  fi
+  if getent group mysql >/dev/null 2>&1; then
+    groupdel mysql
+  fi
+}
diff --git a/community/mariadb/mysqld b/community/mariadb/mysqld
new file mode 100755
index 000000000..e9fe8f5a8
--- /dev/null
+++ b/community/mariadb/mysqld
@@ -0,0 +1,77 @@
+#!/bin/bash
+
+# general config
+. /etc/rc.conf
+. /etc/rc.d/functions
+
+getPID() {
+   echo $(pgrep -u mysql mysqld 2>/dev/null);
+}
+
+case "$1" in
+  start)
+    stat_busy "Starting MariaDB Server"
+    [ ! -d /var/run/mysqld ] && install -d -g mysql -o mysql /var/run/mysqld &>/dev/null
+    if [ -z "$(getPID)" ]; then
+       /usr/bin/mysqld_safe --user=mysql &>/dev/null &
+      if [ $? -gt 0 ]; then
+        stat_fail
+        exit 1
+      else
+        timeo=30
+        while [ $timeo -gt 0 ]; do
+          response=`/usr/bin/mysqladmin -uUNKNOWN_USER ping 2>&1` && break
+          echo "$response" | grep -q "mysqld is alive" && break
+          sleep 1
+          let timeo=${timeo}-1
+        done
+        if [ $timeo -eq 0 ]; then
+          stat_fail
+          exit 1
+        else
+          echo $(getPID) > /var/run/mysqld/mysqld.pid
+          add_daemon mysqld
+          stat_done
+        fi
+      fi
+    else
+      stat_fail
+      exit 1
+    fi
+    ;;
+
+  stop)
+    stat_busy "Stopping MariaDB Server"
+    if [ ! -z "$(getPID)" ]; then
+      timeo=30
+      kill $(getPID) &> /dev/null
+      if [ $? -gt 0 ]; then
+        stat_fail
+        exit 1
+      fi
+      while [ ! -z "$(getPID)" -a $timeo -gt 0 ]; do
+        sleep 1
+        let timeo=${timeo}-1
+      done
+      if [ -z "$(getPID)" ]; then
+        rm -f /var/run/mysqld/mysqld.pid &>/dev/null
+        rm_daemon mysqld
+        stat_done
+      else
+        stat_fail
+        exit 1
+      fi
+    else
+      stat_fail
+      exit 1
+    fi
+    ;;
+
+  restart)
+    $0 stop
+    $0 start
+    ;;
+  *)
+    echo "usage: $0 {start|stop|restart}"
+esac
+exit 0