1 files changed, 50 insertions, 0 deletions
diff --git a/gnome-unstable/anjuta/PKGBUILD b/gnome-unstable/anjuta/PKGBUILD
new file mode 100644
index 000000000..320888b6e
--- /dev/null
+++ b/gnome-unstable/anjuta/PKGBUILD
@@ -0,0 +1,50 @@
+# $Id: PKGBUILD 167359 2012-10-01 14:54:15Z heftig $
+# Maintainer: Andreas Radke <andyrtr@archlinux.org>
+# Contributor: Harley Laue <losinggeneration@yahoo.com>
+
+pkgbase=anjuta
+pkgname=('libanjuta' 'anjuta')
+pkgver=3.6.0
+pkgrel=1
+pkgdesc="GNOME Integrated Development Environment (IDE)"
+arch=('i686' 'x86_64')
+license=('GPL')
+makedepends=('vte3' 'gdl' 'autogen' 'devhelp' 'glade' 'libgda' 'subversion' 'gnome-icon-theme' 'vala' 'dconf' 'gnome-doc-utils' 'intltool' 'gobject-introspection' 'itstool')
+url="http://www.anjuta.org/"
+source=(ftp://ftp.gnome.org/pub/gnome/sources/$pkgbase/${pkgver%.*}/$pkgbase-$pkgver.tar.xz)
+options=('!libtool' '!emptydirs')
+sha256sums=('e810213e2f2847b71e05eb21cdaff6b946e9511cef2105158b428eee47be787a')
+
+build() {
+  cd "$pkgbase-$pkgver"
+  PYTHON=/usr/bin/python2 ./configure --prefix=/usr --sysconfdir=/etc \
+      --localstatedir=/var
+  make
+}
+
+package_libanjuta(){
+  pkgdesc="Anjuta runtime library"
+  depends=('gdl')
+  conflicts=('anjuta<3.4.4')
+
+  cd "$pkgbase-$pkgver/libanjuta"
+
+  # j1: Race during linking
+  make -j1 DESTDIR="$pkgdir" install
+}
+
+package_anjuta(){
+  pkgdesc="GNOME Integrated Development Environment (IDE)"
+  depends=('libanjuta' 'vte3' 'autogen' 'devhelp' 'glade' 'libgda' 'subversion' 'gnome-icon-theme' 'vala' 'dconf')
+
+  install=anjuta.install
+
+  cd "$pkgbase-$pkgver"
+  make -j1 DESTDIR="$pkgdir" install
+
+  cd libanjuta
+  make -j1 DESTDIR="$pkgdir" uninstall
+  
+  sed -i "1s|#!/usr/bin/python$|&2|" \
+    $pkgdir/usr/share/anjuta/project/{pygtk,python}/src/main.py
+}