1 files changed, 48 insertions, 0 deletions
diff --git a/java/java-jarjar/PKGBUILD b/java/java-jarjar/PKGBUILD
new file mode 100644
index 000000000..c78d5539e
--- /dev/null
+++ b/java/java-jarjar/PKGBUILD
@@ -0,0 +1,48 @@
+# Maintainer: Luke Shumaker <lukeshu@sbcglobal.net>
+
+# jarjar 1.2 is old, but is the last version that used java-asm3
+# java-asm4 is not packaged
+
+_pkgname=jarjar
+pkgname=java-jarjar
+pkgver=1.2
+_pkgrev=132 # v1.2 wasn't tagged, but this is clearly it
+pkgdesc="Java static linker (instead of the normal dynamic linking)"
+url="https://code.google.com/p/jarjar/"
+license=('Apache')
+
+pkgrel=2
+arch=('any')
+depends=('java-runtime')
+makedepends=('apache-ant' 'java-asm3' 'junit' 'maven')
+
+source=("libre://${_pkgname}-${pkgver}.tar.gz")
+mksource=("${_pkgname}-${pkgver}::svn+http://jarjar.googlecode.com/svn/trunk/jarjar#revision=$_pkgrev")
+mksource() {
+  cd "$srcdir/$_pkgname-$pkgver"
+  rm -f lib/*.jar
+}
+
+build() {
+  cd "$srcdir/$_pkgname-$pkgver"
+
+  ln -sf /usr/share/java/asm-3.jar             lib/asm-3.3.1.jar
+  ln -sf /usr/share/java/asm-commons-3.jar     lib/asm-commons-3.3.1.jar
+  ln -sf /usr/share/java/junit.jar             lib/junit-4.8.1.jar
+  ln -sf /opt/maven/lib/maven-plugin-api-*.jar lib/maven-plugin-api.jar
+  ln -sf /opt/apache-ant/lib/ant.jar           lib/ant.jar
+
+  export CLASSPATH=/usr/share/java/asm-3.jar
+  echo 'includeantruntime false' > build.properties
+  ant jar
+}
+
+package() {
+  cd "$srcdir/$_pkgname-$pkgver"
+  install -d "$pkgdir/usr/share/java/$_pkgname"
+  install -D "dist/$_pkgname-$pkgver.jar" "$pkgdir/usr/share/java/$_pkgname"
+  ln -s "$_pkgname/$_pkgname-$pkgver.jar" "$pkgdir/usr/share/java/$_pkgname.jar"
+}
+
+mkmd5sums=('SKIP')
+md5sums=('cc2698a58f93cdb22c51f039a1b8a56e')