1 files changed, 57 insertions, 0 deletions
diff --git a/multilib-staging/lib32-gtk2/PKGBUILD b/multilib-staging/lib32-gtk2/PKGBUILD
new file mode 100644
index 000000000..3e303e874
--- /dev/null
+++ b/multilib-staging/lib32-gtk2/PKGBUILD
@@ -0,0 +1,57 @@
+# $Id: PKGBUILD 89396 2013-04-29 08:14:33Z alucryd $
+# Maintainer:  Ionut Biru <ibiru@archlinux.org
+# Contributor: Pierre Schmitz <pierre@archlinux.de>
+# Contributor: Mikko Seppälä <t-r-a-y@mbnet.fi>
+
+_pkgbasename=gtk2
+pkgname=lib32-$_pkgbasename
+pkgver=2.24.17
+pkgrel=2
+pkgdesc="The GTK+ Toolkit (v2) (32-bit)"
+arch=('x86_64')
+url="http://www.gtk.org/"
+install=gtk2.install
+depends=(lib32-{'atk>=1.30.0','pango>=1.28.0','cairo>=1.10.0','gdk-pixbuf2>=2.22.1'}
+         lib32-lib{'cups>=1.4.4',xcursor,'xrandr>=1.3','xi>=1.3',xinerama,xcomposite,xdamage}
+         $_pkgbasename)
+makedepends=('pkgconfig' 'gcc-multilib')
+options=('!libtool' '!docs')
+license=('LGPL')
+source=(http://ftp.gnome.org/pub/gnome/sources/gtk+/2.24/gtk+-${pkgver}.tar.xz
+        xid-collision-debug.patch
+        gtk-modules-32.patch)
+sha256sums=('e947b2b460156d98e8e38930b82458e1d613a71eb26e927f966f7081a640f415'
+            'd758bb93e59df15a4ea7732cf984d1c3c19dff67c94b957575efea132b8fe558'
+            '2effb13404442ae266d4c663347e88cd1ca19e9a83b452da1743bac16af9c7b0')
+
+build() {
+  export CC="gcc -m32"
+  export CXX="g++ -m32"
+  export PKG_CONFIG_PATH="/usr/lib32/pkgconfig"
+
+  cd "${srcdir}/gtk+-${pkgver}"
+  patch -Np1 -i "${srcdir}/xid-collision-debug.patch"
+  patch -p1 -i ${srcdir}/gtk-modules-32.patch
+
+  CXX=/bin/false ./configure --prefix=/usr \
+      --sysconfdir=/etc \
+      --localstatedir=/var \
+      --libdir=/usr/lib32 \
+      --with-xinput=yes
+
+  #https://bugzilla.gnome.org/show_bug.cgi?id=655517
+  sed -i -e 's/ -shared / -Wl,-O1,--as-needed\0/g' libtool
+
+  make
+}
+
+package() {
+  cd "${srcdir}/gtk+-${pkgver}"
+  make DESTDIR="${pkgdir}" install
+  rm -rf "${pkgdir}"/etc
+  rm -rf "${pkgdir}"/usr/{include,share}
+
+  cd "${pkgdir}"/usr/bin
+  mv gtk-query-immodules-2.0 gtk-query-immodules-2.0-32
+  rm -f gtk-builder-convert gtk-demo gtk-update-icon-cache
+}