1 files changed, 52 insertions, 0 deletions
diff --git a/multilib-testing/lib32-libdrm/PKGBUILD b/multilib-testing/lib32-libdrm/PKGBUILD
new file mode 100644
index 000000000..c2a1bd2ec
--- /dev/null
+++ b/multilib-testing/lib32-libdrm/PKGBUILD
@@ -0,0 +1,52 @@
+# $Id: PKGBUILD 64044 2012-02-08 21:25:06Z lcarlier $
+# Contributor: Jan de Groot <jgc@archlinux.org>
+
+_pkgbasename=libdrm
+pkgname=lib32-$_pkgbasename
+pkgver=2.4.31
+pkgrel=1
+pkgdesc="Userspace interface to kernel DRM services (32-bit)"
+arch=(x86_64)
+license=('custom')
+depends=('lib32-libpciaccess' $_pkgbasename)
+makedepends=(gcc-multilib)
+options=('!libtool')
+url="http://dri.freedesktop.org/"
+source=(http://dri.freedesktop.org/${_pkgbasename}/${_pkgbasename}-${pkgver}.tar.bz2
+        no-pthread-stubs.patch)
+#	git_fixes.diff)
+md5sums=('b8cf744ec113c6028fe0975b1133b649'
+         '0c423f6f886a3a8d6a8834224de95bcf')
+
+build() {
+  cd "${srcdir}/${_pkgbasename}-${pkgver}"
+
+  export CC="gcc -m32"
+  export CXX="g++ -m32"
+  export PKG_CONFIG_PATH="/usr/lib32/pkgconfig"
+
+  patch -Np1 -i "${srcdir}/no-pthread-stubs.patch"
+
+  # git fixes - currently none
+  # patch -Np1 -i ${srcdir}/git_fixes.diff
+
+  # libtoolize --force
+  autoreconf --force --install
+  ./configure --prefix=/usr --libdir=/usr/lib32 \
+      --enable-udev \
+      --enable-intel \
+      --enable-radeon \
+      --enable-vmwgfx-experimental-api \
+      --enable-nouveau-experimental-api
+  make
+}
+
+package() {
+  cd "${srcdir}/${_pkgbasename}-${pkgver}"
+
+  make DESTDIR="${pkgdir}" install
+
+  rm -rf "${pkgdir}"/usr/{include,share,bin}
+  mkdir -p "$pkgdir/usr/share/licenses"
+  ln -s $_pkgbasename "$pkgdir/usr/share/licenses/$pkgname"
+}