1 files changed, 57 insertions, 0 deletions
diff --git a/multilib-testing/lib32-libpulse/PKGBUILD b/multilib-testing/lib32-libpulse/PKGBUILD
new file mode 100644
index 000000000..dc5875fc0
--- /dev/null
+++ b/multilib-testing/lib32-libpulse/PKGBUILD
@@ -0,0 +1,57 @@
+# $Id: PKGBUILD 61429 2011-12-31 00:45:02Z heftig $
+# Maintainer: Jan "heftig" Steffens <jan.steffens@gmail.com>
+# Contributor: Daniel J Griffiths <ghost1227@archlinux.us>
+# Contributor: Corrado Primier <bardo@aur.archlinux.org>
+# Contributor: William Rea <sillywilly@gmail.com>
+
+_pkgbasename=libpulse
+pkgname=lib32-$_pkgbasename
+pkgdesc="A featureful, general-purpose sound server (32-bit client libraries)"
+pkgver=1.1
+pkgrel=2
+arch=(x86_64)
+url="http://pulseaudio.org/"
+license=(GPL LGPL)
+depends=(lib32-dbus-core lib32-json-c 
+         lib32-libasyncns lib32-libcap lib32-libxtst lib32-libsm lib32-libsndfile
+         $_pkgbasename)
+makedepends=(gcc-multilib libtool-multilib intltool lib32-glib2 lib32-speex lib32-gtk2)
+optdepends=('lib32-alsa-plugins: ALSA support')
+provides=("lib32-pulseaudio=$pkgver")
+conflicts=(lib32-pulseaudio)
+replaces=(lib32-pulseaudio)
+options=(!emptydirs !libtool)
+source=("http://freedesktop.org/software/pulseaudio/releases/pulseaudio-$pkgver.tar.xz")
+sha256sums=('6fe531136f6ebce2d35872a2d2c914278cdc5dcdd5eea516dc52c81f9001f5ee')
+
+_libs="libpulsecommon-$pkgver.la libpulse.la libpulse-simple.la libpulse-mainloop-glib.la libpulsedsp.la"
+
+build() {
+  cd "$srcdir/pulseaudio-$pkgver"
+
+  export CC="gcc -m32"
+  export CXX="g++ -m32"
+  export PKG_CONFIG_PATH="/usr/lib32/pkgconfig"
+
+  ./configure --prefix=/usr \
+    --sysconfdir=/etc \
+    --libdir=/usr/lib32 \
+    --libexecdir=/usr/lib32 \
+    --localstatedir=/var \
+    --disable-hal \
+    --disable-tcpwrap \
+    --disable-rpath \
+    --disable-default-build-tests
+
+  # fight unused direct deps
+  sed -i -e 's/ -shared / -Wl,-O1,--as-needed\0/g' libtool
+
+  make -C src $_libs
+}
+
+package() {
+  cd "$srcdir/pulseaudio-$pkgver"
+  make -j1 -C src DESTDIR="$pkgdir" \
+    lib_LTLIBRARIES="$_libs" install-libLTLIBRARIES
+  make -j1 DESTDIR="$pkgdir" install-pkgconfigDATA
+}