1 files changed, 35 insertions, 0 deletions
diff --git a/multilib/lib32-alsa-plugins/PKGBUILD b/multilib/lib32-alsa-plugins/PKGBUILD
new file mode 100644
index 000000000..4a0ce214d
--- /dev/null
+++ b/multilib/lib32-alsa-plugins/PKGBUILD
@@ -0,0 +1,35 @@
+# $Id: PKGBUILD 40238 2011-02-22 08:27:39Z heftig $
+# Maintainer: Jan "heftig" Steffens <jan.steffens@gmail.com>
+
+_pkgbasename=alsa-plugins
+pkgname=lib32-$_pkgbasename
+pkgver=1.0.24
+pkgrel=1
+pkgdesc="Extra alsa plugins (32-bit)"
+arch=(x86_64)
+url="http://www.alsa-project.org"
+license=(GPL)
+depends=(lib32-alsa-lib $_pkgbasename)
+makedepends=(lib32-{libpulse,jack,speex,libsamplerate} gcc-multilib)
+optdepends=('lib32-libpulse: PulseAudio plugin'
+            'lib32-jack: Jack plugin'
+            'lib32-libsamplerate: libsamplerate resampling plugin'
+            'lib32-speex: libspeexdsp resampling plugin')
+options=('!libtool')
+source=("ftp://ftp.alsa-project.org/pub/plugins/$_pkgbasename-$pkgver.tar.bz2")
+md5sums=('e4d4c90e11ab9d1a117afbbc1edd2b16')
+
+build() {
+  cd "$srcdir/$_pkgbasename-$pkgver"
+
+  export CC="gcc -m32"
+  export PKG_CONFIG_PATH="/usr/lib32/pkgconfig"
+
+  ./configure --prefix=/usr --libdir=/usr/lib32 --disable-avcodec
+  make
+}
+
+package() {
+  cd "$srcdir/$_pkgbasename-$pkgver"
+  make DESTDIR="$pkgdir" install
+}