1 files changed, 36 insertions, 0 deletions
diff --git a/multilib/lib32-json-c/PKGBUILD b/multilib/lib32-json-c/PKGBUILD
new file mode 100644
index 000000000..07670938e
--- /dev/null
+++ b/multilib/lib32-json-c/PKGBUILD
@@ -0,0 +1,36 @@
+# Maintainer: Jan "heftig" Steffens <jan.steffens@gmail.com>
+# Contributor: Geoffroy Carrier <geoffroy.carrier@koon.fr>
+# Contributor: congyiwu <congyiwu AT gmail DOT com>
+
+_pkgbasename=json-c
+pkgname=lib32-$_pkgbasename
+pkgver=0.9
+pkgrel=1
+pkgdesc="A JSON implementation in C (32-bit)"
+url="http://oss.metaparadigm.com/json-c/"
+license=("MIT")
+arch=('x86_64')
+depends=('lib32-glibc' $_pkgbasename)
+makedepends=('gcc-multilib' 'libtool-multilib')
+source=(http://oss.metaparadigm.com/$_pkgbasename/$_pkgbasename-$pkgver.tar.gz)
+md5sums=('3a13d264528dcbaf3931b0cede24abae')
+options=(!libtool)
+build() {
+  cd "$srcdir/$_pkgbasename-$pkgver"
+
+  export CC="gcc -m32"
+  export PKG_CONFIG_PATH="/usr/lib32/pkgconfig"
+
+  ./configure --prefix=/usr --libdir=/usr/lib32
+  make
+}
+
+package() {
+  cd "$srcdir/$_pkgbasename-$pkgver"
+  make DESTDIR="$pkgdir" install
+
+  rm -r "$pkgdir/usr/include"
+
+  mkdir -p "$pkgdir/usr/share/licenses"
+  ln -s $_pkgbasename "$pkgdir/usr/share/licenses/$pkgname"
+}