1 files changed, 39 insertions, 0 deletions
diff --git a/multilib/lib32-libvorbis/PKGBUILD b/multilib/lib32-libvorbis/PKGBUILD
new file mode 100644
index 000000000..6f0b9fb1d
--- /dev/null
+++ b/multilib/lib32-libvorbis/PKGBUILD
@@ -0,0 +1,39 @@
+# $Id: PKGBUILD 33990 2010-11-30 15:16:40Z bluewind $
+# Maintainer: Tobias Kieslich <tobias@archlinux.org>
+# Contributor: dorphell <dorphell@archlinux.org>
+# Contributor: John Proctor <jproctor@prium.net>
+
+_pkgbasename=libvorbis
+pkgname=lib32-$_pkgbasename
+pkgver=1.3.2
+pkgrel=1
+pkgdesc="Vorbis codec library (32-bit)"
+arch=('x86_64')
+license=('custom')
+url="http://www.xiph.org/ogg/vorbis/"
+depends=('lib32-libogg' $_pkgbasename)
+makedepends=(gcc-multilib)
+options=('!libtool')
+source=(http://downloads.xiph.org/releases/vorbis/${_pkgbasename}-${pkgver}.tar.gz)
+md5sums=('c870b9bd5858a0ecb5275c14486d9554')
+
+build() {
+  cd ${srcdir}/${_pkgbasename}-${pkgver}
+
+  export CC="gcc -m32"
+  export CXX="g++ -m32"
+  export PKG_CONFIG_PATH="/usr/lib32/pkgconfig"
+
+  #-march=i686 optimizes too much, strip it out
+  CFLAGS=${CFLAGS/-march=$CARCH} ./configure --prefix=/usr --disable-static --libdir=/usr/lib32
+  make
+}
+
+package() {
+  cd ${srcdir}/${_pkgbasename}-${pkgver}
+  make DESTDIR="${pkgdir}" install
+
+  rm -rf "${pkgdir}"/usr/{include,share,bin}
+  mkdir -p "$pkgdir/usr/share/licenses"
+  ln -s $_pkgbasename "$pkgdir/usr/share/licenses/$pkgname"
+}