1 files changed, 115 insertions, 0 deletions
diff --git a/staging/pulseaudio/PKGBUILD b/staging/pulseaudio/PKGBUILD
new file mode 100644
index 000000000..52965bfa8
--- /dev/null
+++ b/staging/pulseaudio/PKGBUILD
@@ -0,0 +1,115 @@
+# $Id: PKGBUILD 159684 2012-05-26 01:31:15Z heftig $
+# Maintainer: Jan Alexander Steffens (heftig) <jan.steffens@gmail.com>
+# Contributor: Daniel J Griffiths <ghost1227@archlinux.us>
+# Contributor: Corrado Primier <bardo@aur.archlinux.org>
+# Contributor: William Rea <sillywilly@gmail.com>
+
+pkgbase=pulseaudio
+pkgname=(pulseaudio libpulse)
+pkgdesc="A featureful, general-purpose sound server"
+pkgver=2.0
+pkgrel=2
+arch=(i686 x86_64)
+url="http://www.freedesktop.org/wiki/Software/PulseAudio"
+license=(GPL LGPL)
+makedepends=(libasyncns libcap attr libxtst libsm libsamplerate libtool rtkit
+             speex tdb udev dbus-core avahi bluez gconf intltool jack
+             lirc-utils openssl fftw orc json-c gtk2 webrtc-audio-processing
+             libsystemd)
+options=(!emptydirs !libtool)
+source=(http://freedesktop.org/software/$pkgbase/releases/$pkgbase-$pkgver.tar.xz
+        pulseaudio.xinit 0001-Remove-usage-of-deprecated-udev_get_-_path.patch)
+sha256sums=('28b42edd42f4879a6884af5f0ec11801ac001eb7582881215b36649aa37e2061'
+            'a0db6cdc74fbf0ca10e2343c08e1e228f109221c6c0ff91b0bfade5c4bdf03cf'
+            '13e3cbe5499e462e8d818aa1faa2419aa880888ec18b4757cabbd7f5fcd6e803')
+
+build() {
+  cd $pkgbase-$pkgver
+
+  # libudev.so.1.0.0
+  patch -Np1 -i ../0001-Remove-usage-of-deprecated-udev_get_-_path.patch
+
+  ./configure --prefix=/usr \
+    --sysconfdir=/etc \
+    --libexecdir=/usr/lib \
+    --localstatedir=/var \
+    --with-udev-rules-dir=/usr/lib/udev/rules.d \
+    --with-database=tdb \
+    --disable-hal \
+    --disable-tcpwrap \
+    --disable-rpath \
+    --disable-default-build-tests
+
+  # fight unused direct deps
+  sed -i -e 's/ -shared / -Wl,-O1,--as-needed\0/g' libtool
+
+  make
+}
+
+package_pulseaudio() {
+  depends=("libpulse=$pkgver-$pkgrel" rtkit libltdl speex tdb udev fftw orc
+           libsamplerate webrtc-audio-processing libsystemd)
+  optdepends=('avahi: zeroconf support'
+              'bluez: bluetooth support'
+              'gconf: configuration through gconf (paprefs)'
+              'jack: jack support'
+              'lirc-utils: infra-red support'
+              'openssl: RAOP support'
+              'python2-pyqt: Equalizer GUI (qpaeq)')
+  backup=(etc/pulse/{daemon.conf,default.pa,system.pa})
+  install=pulseaudio.install
+
+  cd $pkgbase-$pkgver
+  make -j1 DESTDIR="$pkgdir" install
+
+  # Lower resample quality, saves CPU
+  sed -e '/resample-method/iresample-method=speex-float-0' \
+      -i "$pkgdir/etc/pulse/daemon.conf"
+
+  # Disable cork-request module, can result in e.g. media players unpausing
+  # when there's a Skype call incoming
+  sed -e 's|/usr/bin/pactl load-module module-x11-cork-request|#&|' \
+      -i "$pkgdir/usr/bin/start-pulseaudio-x11"
+
+  # Make ConsoleKit optional
+  sed -e $'/load-module module-console-kit/{i.nofail\n;a.fail\n;}' \
+      -i "$pkgdir/etc/pulse/default.pa"
+
+  # Python fix
+  sed -i '1s:python$:&2:' "$pkgdir/usr/bin/qpaeq"
+
+  install -Dm755 "$srcdir/pulseaudio.xinit" "$pkgdir/etc/X11/xinit/xinitrc.d/pulseaudio"
+
+  rm "$pkgdir/etc/dbus-1/system.d/pulseaudio-system.conf"
+
+### Split libpulse
+
+  mkdir -p "$srcdir"/libpulse/{etc/pulse,usr/{lib/pulseaudio,share/man/man5}}
+
+  mv {"$pkgdir","$srcdir/libpulse"}/etc/pulse/client.conf
+
+  mv "$pkgdir"/usr/lib/libpulse{,-simple,-mainloop-glib}.so* \
+     "$srcdir/libpulse/usr/lib"
+
+  mv "$pkgdir"/usr/lib/pulseaudio/libpulsedsp.so \
+     "$pkgdir"/usr/lib/pulseaudio/libpulsecommon-*.so \
+     "$srcdir/libpulse/usr/lib/pulseaudio"
+
+  mv {"$pkgdir","$srcdir/libpulse"}/usr/lib/cmake
+  mv {"$pkgdir","$srcdir/libpulse"}/usr/lib/pkgconfig
+
+  mv {"$pkgdir","$srcdir/libpulse"}/usr/include
+
+  mv {"$pkgdir","$srcdir/libpulse"}/usr/share/man/man5/pulse-client.conf.5
+  mv {"$pkgdir","$srcdir/libpulse"}/usr/share/vala
+}
+
+package_libpulse() {
+  pkgdesc="$pkgdesc (client library)"
+  depends=(dbus-core libasyncns libcap libxtst libsm libsndfile json-c)
+  optdepends=('alsa-plugins: ALSA support'
+              'avahi: zeroconf support')
+  backup=(etc/pulse/client.conf)
+
+  mv "$srcdir"/libpulse/* "$pkgdir"
+}