1 files changed, 40 insertions, 0 deletions
diff --git a/testing/libpst/PKGBUILD b/testing/libpst/PKGBUILD
new file mode 100644
index 000000000..484181df0
--- /dev/null
+++ b/testing/libpst/PKGBUILD
@@ -0,0 +1,40 @@
+# $Id: PKGBUILD 163549 2012-07-15 13:17:02Z ibiru $
+# Maintainer: Jan de Groot <jgc@archlinux.org>
+
+pkgbase=libpst
+pkgname=('libpst' 'libpst-docs')
+pkgver=0.6.54
+pkgrel=2
+arch=('i686' 'x86_64')
+url="http://www.five-ten-sg.com/libpst/"
+license=('GPL')
+makedepends=('python2' 'boost')
+source=(http://www.five-ten-sg.com/libpst/packages/${pkgbase}-${pkgver}.tar.gz)
+sha1sums=('a4713b87e330556acb0786b4efa975a3c739cd84')
+
+build() {
+  cd "${srcdir}/${pkgbase}-${pkgver}"
+  ./configure --prefix=/usr --mandir=/usr/share/man \
+      --disable-static --enable-libpst-shared --disable-dii PYTHON_VERSION=2
+  make
+}
+
+package_libpst() {
+  pkgdesc="Outlook .pst file converter"
+  depends=('gcc-libs')
+  optdepends=('boost-libs: for libpst python interface')
+  options=('!libtool' '!docs')
+
+  cd "${srcdir}/${pkgbase}-${pkgver}"
+  make DESTDIR="${pkgdir}" install
+}
+
+package_libpst-docs() {
+  pkgdesc="Documentation for Outlook .pst file converter"
+  options=('!libtool')
+
+  cd "${srcdir}/${pkgbase}-${pkgver}"
+  make DESTDIR="${pkgdir}" install-htmlDATA
+  cd "${srcdir}/${pkgbase}-${pkgver}/html"
+  make DESTDIR="${pkgdir}" install-htmldevelDATA
+}