2 files changed, 69 insertions, 0 deletions
diff --git a/testing/curl/PKGBUILD b/testing/curl/PKGBUILD
new file mode 100644
index 000000000..fe72fa227
--- /dev/null
+++ b/testing/curl/PKGBUILD
@@ -0,0 +1,60 @@
+# $Id: PKGBUILD 137981 2011-09-13 20:49:30Z dreisner $
+# Maintainer: Dave Reisner <dreisner@archlinux.org>
+# Contributor: Angel Velasquez <angvp@archlinux.org>
+# Contributor: Eric Belanger <eric@archlinux.org>
+# Contributor: Lucien Immink <l.immink@student.fnt.hvu.nl>
+# Contributor: Daniel J Griffiths <ghost1227@archlinux.us>
+
+pkgname=curl
+pkgver=7.22.0
+pkgrel=1
+pkgdesc="An URL retrival utility and library"
+arch=('i686' 'x86_64')
+url="http://curl.haxx.se"
+license=('MIT')
+depends=('zlib' 'openssl' 'bash' 'ca-certificates' 'libssh2')
+options=('!libtool')
+source=("http://curl.haxx.se/download/$pkgname-$pkgver.tar.gz"{,.asc}
+        curlbuild.h)
+md5sums=('e8c36126d21c893f085aca233906b5cc'
+         '1b061c348b63ea3e90c3f2c3af6a08d6'
+         '751bd433ede935c8fae727377625a8ae')
+
+
+case $(cpp <<<'__SIZEOF_POINTER__' | sed '/^#/d') in
+  8) _curlbuild=curlbuild-64.h ;;
+  4) _curlbuild=curlbuild-32.h ;;
+  *) error "unsupported architecture: %s" "$CARCH"
+    exit 1
+    ;;
+esac
+
+build() {
+  cd "$srcdir/$pkgname-$pkgver"
+
+  ./configure \
+      --with-random=/dev/urandom \
+      --prefix=/usr \
+      --mandir=/usr/share/man \
+      --disable-dependency-tracking \
+      --enable-ipv6 \
+      --disable-ldaps \
+      --disable-ldap \
+      --enable-manual \
+      --enable-versioned-symbols \
+      --with-ca-bundle=/etc/ssl/certs/ca-certificates.crt \
+      --without-libidn \
+      --enable-threaded-resolver
+  make
+}
+
+package() {
+  cd "$srcdir/$pkgname-$pkgver"
+
+  make DESTDIR="$pkgdir" install
+
+  install -Dm644 COPYING "$pkgdir/usr/share/licenses/$pkgname/COPYING"
+  install -Dm644 docs/libcurl/libcurl.m4 "$pkgdir/usr/share/aclocal/libcurl.m4"
+  mv "$pkgdir/usr/include/curl/curlbuild.h" "$pkgdir/usr/include/curl/$_curlbuild"
+  install -m644 "$srcdir/curlbuild.h" "$pkgdir/usr/include/curl/curlbuild.h"
+}
diff --git a/testing/curl/curlbuild.h b/testing/curl/curlbuild.h
new file mode 100644
index 000000000..b48862696
--- /dev/null
+++ b/testing/curl/curlbuild.h
@@ -0,0 +1,9 @@
+#include <bits/wordsize.h>
+
+#if __WORDSIZE == 32
+#include "curlbuild-32.h"
+#elif __WORDSIZE == 64
+#include "curlbuild-64.h"
+#else
+#error "Unknown word size"
+#endif