blob: 577c0efdb6eb7297e54cf8eee6edab451507c143 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
|
# $Id: PKGBUILD 78040 2012-10-16 11:50:05Z allan $
# Maintainer: Balló György <ballogyor+arch at gmail dot com>
pkgname=dee
pkgver=1.0.14
pkgrel=2
pkgdesc="Library to provide objects allowing to create Model-View-Controller type programs across DBus"
arch=('i686' 'x86_64')
url="https://launchpad.net/dee"
license=('LGPL')
depends=('glib2' 'icu')
makedepends=('python2' 'gobject-introspection' 'vala')
options=('!libtool')
source=(http://launchpad.net/$pkgname/1.0/$pkgver/+download/$pkgname-$pkgver.tar.gz)
md5sums=('473b4181e26538af0fb753255da7945c')
build() {
cd "$srcdir/$pkgname-$pkgver"
./configure --prefix=/usr --sysconfdir=/etc --localstatedir=/var \
--disable-static --disable-tests \
PYTHON=python2
make
}
package() {
cd "$srcdir/$pkgname-$pkgver"
make DESTDIR="$pkgdir/" install
# Install GI overrides for python 3 as well
install -dm755 "$pkgdir/usr/lib/python3.3/site-packages/gi/overrides"
ln -s ../../../../python2.7/site-packages/gi/overrides/Dee.py "$pkgdir/usr/lib/python3.3/site-packages/gi/overrides/Dee.py"
}
|
