blob: ad7fa29f47551e276bc6c6326e94c173281868a1 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
|
# $Id$
# Maintainer: Sébastien Luttringer <seblu@aur.archlinux.org>
# Contributor: Andrea Zucchelli <zukka77@gmail.com>
pkgname=keepalived
pkgver=1.2.2
pkgrel=3
pkgdesc='Failover and monitoring daemon for LVS clusters'
arch=('i686' 'x86_64')
url='http://www.keepalived.org/'
license=('GPL2')
backup=('etc/keepalived/keepalived.conf' 'etc/conf.d/keepalived')
depends=('openssl' 'popt' 'libnl1')
source=("http://www.keepalived.org/software/$pkgname-$pkgver.tar.gz"
'keepalived.rc'
'keepalived.conf'
'ip_vs_moved.patch')
md5sums=('f68327ca142616a8463d2d105db122cd'
'baeb62a682c2b59d732cea84bf52cc87'
'9c8142da8730ad27a345587dea83ced7'
'87ee19c85adaedd3eb11bea8a5865d47')
build() {
cd $pkgname-$pkgver
patch -p1 -i ../ip_vs_moved.patch
./configure --prefix=/usr --sysconfdir=/etc
make
}
package() {
cd $pkgname-$pkgver
make DESTDIR="$pkgdir" install
# clean pacakge init scripts
rm -r "$pkgdir/etc/rc.d/init.d" "$pkgdir/etc/sysconfig"
# move examples to /usr/share
install -d -m 755 "$pkgdir/usr/share/$pkgname"
mv "$pkgdir/etc/keepalived/samples" "$pkgdir/usr/share/$pkgname/samples"
# add initscripts
install -D -m 755 ../$pkgname.rc "${pkgdir}/etc/rc.d/$pkgname"
install -D -m 644 ../$pkgname.conf "${pkgdir}/etc/conf.d/$pkgname"
}
# vim:set ts=2 sw=2 ft=sh et:
|
