blob: a510a3e0fe7ada29b4a404e919a26d9252c9dcca (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
|
# $Id: PKGBUILD 105861 2014-02-16 16:38:12Z bpiotrowski $
# Maintainer: Sven-Hendrik Haase <sh@lutzhaase.com>
# Contributor: t3ddy <t3ddy1988 "at" gmail {dot} com>
# Contributor: Adrián Chaves Fernández (Gallaecio) <adriyetichaves@gmail.com>
pkgname=0ad
pkgver=a15
_pkgver=0.0.15-alpha
pkgrel=3
pkgdesc="Cross-platform, 3D and historically-based real-time strategy game"
arch=('i686' 'x86_64')
url="http://play0ad.com/"
license=('GPL2' 'CCPL')
depends=('binutils' 'boost-libs' 'curl' 'enet' 'libogg' 'libpng' 'libvorbis'
'libxml2' 'openal' 'sdl' 'wxgtk2.8' 'zlib' 'libgl' '0ad-data' 'glu'
'gloox' 'miniupnpc' 'libsm')
makedepends=('boost' 'cmake' 'mesa' 'zip' 'python2')
source=("http://releases.wildfiregames.com/$pkgname-$_pkgver-unix-build.tar.xz")
md5sums=('a651d81eb9b31da01e376ddaa597e954')
build() {
cd "$srcdir/$pkgname-$_pkgver/build/workspaces"
unset CPPFLAGS # for le spidermonkey
export WX_CONFIG=/usr/bin/wx-config-2.8
./update-workspaces.sh \
--with-system-enet \
--bindir=/usr/bin \
--libdir=/usr/lib/0ad \
--datadir=/usr/share/${pkgname}/data
cd "$srcdir/$pkgname-$_pkgver/build/workspaces/gcc"
make CONFIG=Release
}
package() {
install -d "${pkgdir}"/usr/{bin,lib/0ad}
cd "$srcdir/$pkgname-$_pkgver"
install -Dm755 binaries/system/pyrogenesis "${pkgdir}/usr/bin"
install -Dm755 binaries/system/*.so{,.1.0} "${pkgdir}/usr/lib/0ad"
install -Dm755 build/resources/${pkgname}.sh "${pkgdir}/usr/bin/${pkgname}"
install -Dm644 build/resources/${pkgname}.desktop \
"${pkgdir}/usr/share/applications/${pkgname}.desktop"
install -Dm644 build/resources/${pkgname}.png \
"${pkgdir}/usr/share/pixmaps/${pkgname}.png"
}
|
