blob: 7ab054c750e722c4eb22f96b681c2ce64df30522 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
|
# $Id: PKGBUILD 68209 2012-03-19 09:36:12Z arodseth $
# Maintainer: Alexander Rødseth <rodseth@gmail.com>
# Contributor: Ionut Biru <ibiru@archlinux.org>
# Contributor: Tom Newsom <Jeepster@gmx.co.uk>
# Contributor: arjan <arjan@archlinux.org>
pkgname=allegro
pkgver=5.0.6
pkgrel=2
pkgdesc="Portable library mainly aimed at video game and multimedia programming"
arch=('x86_64' 'i686')
url="http://alleg.sourceforge.net/"
license=('custom')
depends=('jack' 'libxpm' 'freetype2' 'libxxf86dga' 'libxcursor' 'libpng' 'libgl' 'libjpeg' 'physfs')
makedepends=('cmake' 'mesa')
source=("http://downloads.sourceforge.net/alleg/$pkgname-$pkgver.tar.gz")
sha256sums=('d981a1cac937085e6636e597c492ddb743066516c1d215c2a39e4049bd70dc24')
build() {
cd "$srcdir"
mkdir build
cd build
cmake "../$pkgname-$pkgver" \
-DCMAKE_BUILD_TYPE=Release \
-DCMAKE_INSTALL_PREFIX=/usr \
-DWANT_DOCS=OFF \
-DWANT_PHYSFS=ON
make
}
package() {
cd "$srcdir/build"
make DESTDIR="$pkgdir" install
install -Dm644 "../$pkgname-$pkgver/LICENSE.txt" \
"$pkgdir/usr/share/licenses/$pkgname/LICENSE"
}
# vim:set ts=2 sw=2 et:
|
