blob: 009fb566b4a146fdbe7075001c167c1fc6efe6e3 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
|
# Maintainer: Lukas Fleischer <archlinux at cryptocrack dot de>
# Contributor: Markus Martin <markus@archwyrm.net>
pkgname=alure
pkgver=1.2
pkgrel=3
pkgdesc='Utility library to help manage common tasks with OpenAL applications.'
arch=('i686' 'x86_64')
url='http://kcat.strangesoft.net/alure.html'
license=('MIT')
depends=('openal')
makedepends=('cmake' 'libsndfile' 'libvorbis' 'flac' 'mpg123' 'dumb' 'fluidsynth')
optdepends=('libsndfile: for uncompressed audio support'
'libvorbis: for OGG Vorbis support'
'flac: for FLAC support'
'mpg123: for MPEG support'
'dumb: for IT, XM, S3M and MOD support'
'fluidsynth: for SoundFont 2 support')
source=("http://kcat.strangesoft.net/alure-releases/${pkgname}-${pkgver}.tar.bz2"
build.patch)
md5sums=('3088aba074ad02d95ea51e705053b9f5'
'6a8dfd62ccae920d393b4202736aba46')
prepare() {
cd $pkgname-$pkgver
patch -p1 -i ../build.patch
}
build() {
cd "${srcdir}/${pkgname}-${pkgver}"
cmake . -DCMAKE_INSTALL_PREFIX=/usr
make
}
package() {
cd "${srcdir}/${pkgname}-${pkgver}"
make DESTDIR="${pkgdir}" install
install -Dm0644 COPYING "${pkgdir}/usr/share/licenses/${pkgname}/COPYING"
}
|
