blob: cce37eba5323ae000c2d9f04db639d5886c4d2d8 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
|
# $Id: PKGBUILD 103391 2014-01-05 15:54:47Z bpiotrowski $
# Maintainer: Bartłomiej Piotrowski <nospam@bpiotrowski.pl>
# Contributor: Thomas Dziedzic < gostrc at gmail >
# Contributor: Angel Velasquez <angvp@archlinux.org>
# Contributor: Alexander Fehr <pizzapunk gmail com>
# Contributor: Daniel J Griffiths <ghost1227@archlinux.us>
pkgname=aria2
pkgver=1.18.3
pkgrel=1
pkgdesc='Download utility that supports HTTP(S), FTP, BitTorrent, and Metalink'
arch=('i686' 'x86_64')
url='http://aria2.sourceforge.net/'
license=('GPL')
depends=('gnutls' 'libxml2' 'sqlite' 'c-ares' 'ca-certificates')
checkdepends=('cppunit')
source=(http://downloads.sourceforge.net/aria2/aria2-$pkgver.tar.xz)
sha256sums=('014706c67406be380384484635ca2e811b405c876f0bbcf7a31be79df392d84d')
build() {
cd $pkgname-$pkgver
./configure \
--prefix=/usr \
--with-ca-bundle=/etc/ssl/certs/ca-certificates.crt
make
}
check() {
cd $pkgname-$pkgver
make check
}
package() {
cd $pkgname-$pkgver
make DESTDIR="$pkgdir" install
# add bash completion
install -d "$pkgdir"/usr/share/bash-completion/completions
install -m644 "$pkgdir"/usr/share/doc/aria2/bash_completion/aria2c \
"$pkgdir"/usr/share/bash-completion/completions
rm -rf "$pkgdir"/usr/share/doc/aria2/bash_completion
}
|
