blob: 6f03f7db550abee319ce4fcdfba0fe2d2c658a39 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
|
# $Id: PKGBUILD 41838 2011-03-09 17:53:24Z lfleischer $
# Maintainer: Lukas Fleischer <archlinux at cryptocrack dot de>
# Contributor: Andrea Scarpino <andrea@archlinux.org>
# Contributor: Dale Blount <dale@archlinux.org>
# Contributor: Manolis Tzanidakis
pkgname=autofs
pkgver=5.0.5
pkgrel=5
pkgdesc='A kernel-based automounter for Linux.'
arch=('i686' 'x86_64')
url='http://freshmeat.net/projects/autofs'
license=('GPL2')
depends=('libldap' 'libxml2' 'heimdal')
backup=('etc/autofs/auto.master'
'etc/autofs/auto.misc'
'etc/conf.d/autofs')
options=(!makeflags)
install='autofs.install'
source=("http://www.kernel.org/pub/linux/daemons/${pkgname}/v5/${pkgname}-${pkgver}.tar.bz2"
'autofs'
'autofs.conf.d'
'auto.master'
'auto.misc'
'heimdal.patch')
md5sums=('a1d262cb6ebef0c2dd0fe22232fb3d5a'
'e307bf6d2638e46eeb916cf42fe029b2'
'47f597c870410055e0fdb66103daf928'
'a6cefb591e77b31b79dbb7243646c96b'
'd8a15ec9186c5c0b36e5cea1e2739e8a'
'efd46b6406b940cb48f7c6197790fb8e')
build() {
cd "${srcdir}/${pkgname}-${pkgver}"
sed -i "s:SUBDIRS = lib daemon modules man samples:SUBDIRS = lib daemon modules man:" \
Makefile.rules
patch -Np1 -i "${srcdir}/heimdal.patch"
./configure --prefix=/usr --sysconfdir=/etc/autofs --with-mapdir=/etc/autofs --without-hesiod \
--enable-ignore-busy
make
}
package() {
cd "${srcdir}/${pkgname}-${pkgver}"
make INSTALLROOT="${pkgdir}" install
install -Dm0644 "${srcdir}/auto.master" "${pkgdir}/etc/autofs/auto.master"
install -Dm0644 "${srcdir}/auto.misc" "${pkgdir}/etc/autofs/auto.misc"
install -Dm0755 "${srcdir}/autofs" "${pkgdir}/etc/rc.d/autofs"
install -Dm0644 "${srcdir}/autofs.conf.d" "${pkgdir}/etc/conf.d/autofs"
}
|
