blob: 6e14be9e296aa3949b6a36cb8fd8b3b373eb9ab4 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
|
# $Id: PKGBUILD 98638 2013-10-16 01:00:11Z seblu $
# Maintainer: Sébastien Luttringer
# Contributor: xduugu
# Contributor: Ronald van Haren <ronald.archlinux.org>
# Contributor: Vesa Kaihlavirta
pkgname=awesome
pkgver=3.5.2
pkgrel=1
pkgdesc='Highly configurable framework window manager'
arch=('i686' 'x86_64')
url='http://awesome.naquadah.org/'
license=('GPL2')
depends=(
'cairo'
'dbus'
'gdk-pixbuf2'
'imlib2'
'libxdg-basedir'
'lua'
'lua-lgi'
'pango'
'startup-notification'
'xcb-util-cursor'
'xcb-util-keysyms'
'xcb-util-wm'
'xorg-xmessage'
)
makedepends=(
'asciidoc'
'cmake'
'docbook-xsl'
'doxygen'
'imagemagick'
'ldoc'
'xmlto'
)
optdepends=(
'rlwrap: readline support for awesome-client'
'dex: autostart your desktop files'
'vicious: widgets for the Awesome window manager'
)
provides=('notification-daemon')
backup=('etc/xdg/awesome/rc.lua')
source=("$url/download/$pkgname-$pkgver.tar.xz")
md5sums=('c16eaaaddf6f56b4e041007952e2a4fe')
build() {
cd $pkgname-$pkgver
cmake \
-DCMAKE_BUILD_TYPE=RELEASE \
-DCMAKE_INSTALL_PREFIX=/usr \
-DSYSCONFDIR=/etc \
-DLUA_LIBRARY=/usr/lib/liblua.so.5.2
make
}
package() {
cd $pkgname-$pkgver
make DESTDIR="$pkgdir" install
# install desktop file so you can start awesome from your login manager
install -Dm644 awesome.desktop "$pkgdir/usr/share/xsessions/awesome.desktop"
}
# vim:set ts=2 sw=2 et:
|
