blob: 7abc25c168361261672280b8c848a151c75ac1eb (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
|
# $Id: PKGBUILD 78176 2012-10-17 10:22:59Z allan $
# Maintainer : Ionut Biru <ibiru@archlinux.org
# Contributor: Abhishek Dasgupta <abhidg@gmail.com>
pkgname=blueman
pkgver=1.23
pkgrel=5
pkgdesc="GTK+ bluetooth manager"
arch=('i686' 'x86_64')
license=('GPL')
url="http://blueman-project.org"
depends=('python2-notify' 'bluez' 'python2-dbus' 'gtk2' 'python2-gobject2' 'startup-notification'
'obex-data-server' 'polkit-gnome' 'xdg-utils' 'hicolor-icon-theme' 'libpulse'
'notification-daemon')
makedepends=('pyrex' 'intltool')
optdepends=('dnsmasq: For creating PAN network'
'gconf: For gconf configuration support'
'pulseaudio: To use the pulseaudio plugin'
'notification-daemon: for desktop notifications'
'libnotify: for desktop notifications'
'modemmanager: for modem management service'
'gnome-icon-theme: icon theme')
options=('!libtool')
install=$pkgname.install
source=(http://download.tuxfamily.org/blueman/${pkgname}-${pkgver}.tar.gz)
md5sums=('f0bee59589f4c23e35bf08c2ef8acaef')
build() {
cd "${srcdir}/${pkgname}-${pkgver}"
export PYTHON=python2
for file in apps/blueman*; do
sed -i 's_#!/usr/bin/python_#!/usr/bin/python2_' $file
done
sed -i 's|"blueman-tray"|"blueman"|' blueman/plugins/applet/StatusIcon.py
./configure --prefix=/usr \
--sysconfdir=/etc \
--libexecdir=/usr/lib/blueman \
--with-no-runtime-deps-check
make
}
package() {
cd "${srcdir}/${pkgname}-${pkgver}"
make DESTDIR="${pkgdir}" install
echo "OnlyShowIn=GNOME;XFCE;" >> ${pkgdir}/etc/xdg/autostart/blueman.desktop
}
|
