blob: e5e7361302bd5d66d4322a0ef36f9bf216f009c9 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
|
# $Id: PKGBUILD 105391 2014-02-06 16:23:43Z andyrtr $
# Maintainer: Maxime Gauduin <alucryd at gmail dot com>
# Contributor: Tofe <chris dot chapuis at gmail dot com>
# Contributor: zhuqin <zhuqin83 at gmail dot com>
# Contributor: tri1976 <trile7 at gmail dot com>
# Contributor: snoopy33 <snoopy33 at no dash log dot org>
pkgname=cairo-dock-plugins
pkgver=3.3.2
pkgrel=2
pkgdesc='Plugins for Cairo-Dock'
arch=('i686' 'x86_64')
url="https://launchpad.net/${pkgname%-*}-plug-ins"
license=('GPL')
depends=('cairo-dock')
makedepends=('cmake' 'alsa-lib' 'fftw' 'gnome-menus' 'gtk-sharp-2' 'gvfs' 'libetpan' 'libexif' 'libical' 'libpulse' 'libxklavier' 'libzeitgeist' 'lm_sensors' 'ndesk-dbus-glib' 'python' 'python2' 'ruby' 'upower' 'vala' 'vte3' 'webkitgtk3')
optdepends=('alsa-lib: Sound Control, Sound Effects applets'
'fftw: Impulse applet'
'gnome-menus: Applications Menu applet'
'gtk-sharp-2: Mono API'
'gvfs: GVFS integration'
'libetpan: Mail applet'
'libexif: Slider applet'
'libical: Clock applet'
'libpulse: Impulse applet'
'libxklavier: Keyboard Indicator applet'
'libzeitgeist: Recent Events applet'
'lm_sensors: System Monitor applet'
'ndesk-dbus-glib: Mono API'
'python: Python 3 API'
'python2: Python 2 API'
'ruby: Ruby API'
'upower: Logout, PowerManager applets'
'vte3: Terminal applet'
'webkitgtk3: Weblets applet')
source=("${url}/${pkgver%.?}/${pkgver}/+download/${pkgname}-${pkgver}.tar.gz")
sha256sums=('48f0caddb0a563d8a64176f66610ca35df5c952071e5574486d39bb574994643')
build() {
cd ${pkgname}-${pkgver}
if [[ -d build ]]; then
rm -rf build
fi
mkdir build && cd build
cmake .. -DCMAKE_INSTALL_PREFIX='/usr'
make
}
package() {
cd ${pkgname}-${pkgver}/build
make DESTDIR="${pkgdir}" install
}
# vim: ts=2 sw=2 et:
|
