blob: 140834e21ea92d917caff01bb3e82bdd792aa7d8 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
|
# $Id: PKGBUILD 75213 2012-08-16 09:19:22Z stativ $
# Maintainer: Lukas Jirkovsky <l.jirkovsky@gmail.com>
pkgname=cdrtools
pkgver=3.01a08
pkgrel=1
pkgdesc="Original cdrtools supporting CD, DVD and BluRay burning"
arch=('i686' 'x86_64')
url="http://cdrecord.berlios.de/private/cdrecord.html"
license=('CDDL')
depends=('acl')
conflicts=('cdrkit')
provides=('cdrkit')
options=(!makeflags)
backup=('etc/default/cdrecord' 'etc/default/rscsi')
install=cdrtools.install
source=(ftp://ftp.berlios.de/pub/cdrecord/alpha/cdrtools-$pkgver.tar.gz)
md5sums=('bed40540ef0dfc41d4b6e62c70012a01')
build() {
cd "$srcdir"/cdrtools-${pkgver%%a*}
sed -i 's|/opt/schily|/usr|g' DEFAULTS/Defaults.linux
sed -i 's|DEFINSGRP=.*|DEFINSGRP=root|' DEFAULTS/Defaults.linux
export GMAKE_NOWARN=true
make INS_BASE=/usr INS_RBASE=/
}
package() {
cd "$srcdir"/cdrtools-${pkgver%%a*}
export GMAKE_NOWARN=true
make INS_BASE=/usr INS_RBASE=/ DESTDIR="$pkgdir" install
rm -rf "$pkgdir"/usr/include
rm -rf "$pkgdir"/usr/lib/{*.a,profiled}
# autoload 'sg' module needed by cdrecord
install -d -m755 "$pkgdir"/usr/lib/modules-load.d/
echo sg > "$pkgdir"/usr/lib/modules-load.d/cdrecord.conf
}
# vim:set ts=2 sw=2 et:
|
