blob: eba1479018379f65ed7fa4bef7bda4ec24bf4af4 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
|
# $Id: PKGBUILD 105550 2014-02-10 04:57:25Z kkeen $
# Maintainer: Kyle Keen <keenerd@gmail.com>
# Contributor: Dmitriy Morozov <foxcub>
pkgname=cgal
pkgver=4.3
pkgrel=2
_pkgid=32995
pkgdesc="Computational Geometry Algorithms Library"
arch=('i686' 'x86_64')
url="http://www.cgal.org"
license=('GPL' 'LGPL')
source=(http://gforge.inria.fr/frs/download.php/$_pkgid/CGAL-$pkgver.tar.xz)
depends=('mpfr' 'boost-libs' 'gmp' 'mesa' 'glu')
optdepends=('qt4: for CGAL_Qt4'
'eigen: for some packages, see the CGAL manual')
makedepends=('cmake' 'qt4' 'eigen' 'boost')
md5sums=('c0af5e3a56300b0c92ebd3a1f0df9149')
# consider building with swig for python stuff
build() {
cd "$srcdir/CGAL-$pkgver"
mkdir build
cd build
cmake ../ -DCMAKE_BUILD_TYPE=Release -DCMAKE_INSTALL_PREFIX=/usr
make
}
package() {
cd "$srcdir/CGAL-$pkgver/build"
make install DESTDIR="$pkgdir"
# The tarball still has all theese licenses included
for _license in LICENSE{,.FREE_USE,.GPL,.LGPL}; do
install -D -m644 "$srcdir/CGAL-$pkgver/$_license" "$pkgdir/usr/share/licenses/$pkgname/$_license"
done
}
|
