blob: bdda0434f7d28bbc4957d1fc568b15c00e91824d (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
|
# $Id: PKGBUILD 88266 2013-04-15 11:13:22Z spupykin $
# Maintainer: Sergej Pupykin <pupykin.s+arch@gmail.com>
# Current Maintainer: Patrick Palka <patrick@parcs.ath.cx>
# Previous Maintainer: Loui Chang <louipc.ist at gmail com>
# Contributor: Andreas Baumann <abaumann at yahoo dot com>
# Development: http://closure.ath.cx/aur-dev
pkgname=cgit
pkgver=0.9.1
_gitver=1.7.4
pkgrel=2
pkgdesc="A web interface for git written in plain C"
arch=('i686' 'x86_64' 'mips64el')
url="http://hjemli.net/git/cgit"
license=('GPL')
depends=('openssl')
makedepends=('zlib' 'curl' 'asciidoc')
install=cgit.install
source=("http://git.zx2c4.com/cgit/snapshot/cgit-$pkgver.tar.xz"
"git-${_gitver}.tar.gz::https://github.com/git/git/archive/v${_gitver}.tar.gz"
"apache.example.conf")
md5sums=('272ee8fec2d81ac1e65117578e64df1e'
'c63cc7ca8a4bbf97c8802f354511223e'
'bd5696bea0654bfcf98f249b1a36737d')
build() {
cd "$pkgname-$pkgver"
_cgit_gitver=`grep 'GIT_VER = ' Makefile | cut -f3 -d\ `
[ "x${_gitver}" == "x${_cgit_gitver}" ] || { msg "Bad git version"; return 1; }
rm -rf git/*
mv ../git-${_gitver}/* git/
make
make doc-man
}
package() {
cd "$pkgname-$pkgver"
make CGIT_SCRIPT_PATH=/usr/share/webapps/cgit DESTDIR="$pkgdir" install install-man
install -vDm644 COPYING "$pkgdir/usr/share/licenses/$pkgname/COPYING"
install -vd "$pkgdir/var/cache/$pkgname"
install -vDm0644 $srcdir/apache.example.conf $pkgdir/etc/webapps/cgit/apache.example.conf
mkdir -p $pkgdir/usr/lib/cgit
mv $pkgdir/usr/share/webapps/cgit/cgit.cgi $pkgdir/usr/lib/cgit
ln -sf ../../../lib/cgit/cgit.cgi $pkgdir/usr/share/webapps/cgit/cgit.cgi
}
|
