blob: 6820abb1d784a2d457fb5253783b42910b9ffd30 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
|
# $Id: PKGBUILD 101563 2013-11-28 01:18:16Z faidoc $
# Maintainer: Alexandre Filgueira <alexfilgueira@cinnarch.com
# Based on gnome-control-center:
# Jan Alexander Steffens (heftig) <jan.steffens@gmail.com>
# Jan de Groot <jgc@archlinux.org>
pkgname=cinnamon-control-center
pkgver=2.0.9
pkgrel=1
pkgdesc="The Control Center for Cinnamon"
arch=('i686' 'x86_64')
depends=('cinnamon-settings-daemon' 'cinnamon-translations' 'gnome-menus' 'libgnomekbd' 'network-manager-applet')
optdepends=('gnome-color-manager: for color management tasks')
makedepends=('intltool' 'gnome-common' 'docbook-xsl')
url="https://github.com/linuxmint/cinnamon-control-center"
install=cinnamon-control-center.install
license=('GPL')
options=('!emptydirs')
source=("$pkgname-$pkgver.tar.gz::https://github.com/linuxmint/cinnamon-control-center/archive/$pkgver.tar.gz"
region.patch)
sha256sums=('63bb179a50d5f873ed1c19de97966592eedbc055ce2829e4298223a75fc33b4e'
'077cb8d6814c32a4df85f71c2b8fa84da25e5260263a6e0536c6e1626051f022')
prepare() {
cd $pkgname-$pkgver
# Fix region panel
patch -Np1 -i ../region.patch
}
build() {
cd $pkgname-$pkgver
./autogen.sh --prefix=/usr --sysconfdir=/etc \
--localstatedir=/var --disable-static \
--enable-systemd \
--disable-update-mimedb
#https://bugzilla.gnome.org/show_bug.cgi?id=656229
sed -i -e 's/ -shared / -Wl,-O1,--as-needed\0 /g' -e 's/ if test "$export_dynamic" = yes && test -n "$export_dynamic_flag_spec"; then/ func_append compile_command " -Wl,-O1,--as-needed"\n func_append finalize_command " -Wl,-O1,--as-needed"\n\0/' libtool
make
}
package() {
cd $pkgname-$pkgver
make DESTDIR="$pkgdir" install
# Remove unused stuff
make -C panels/sound DESTDIR="$pkgdir" uninstall
make -C panels/sound/data DESTDIR="$pkgdir" install
make -C shell DESTDIR="$pkgdir" uninstall-binPROGRAMS uninstall-directoryDATA uninstall-uiDATA
rm -R "$pkgdir/usr/share/applications"
rm -R "$pkgdir/etc"
# Fix a warning
chown 102:0 "$pkgdir/usr/share/polkit-1/rules.d"
chmod 700 "$pkgdir/usr/share/polkit-1/rules.d"
}
|
