blob: 23e14844be1213d2114a446e73014ac2275f39de (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
|
# $Id: PKGBUILD 71904 2012-06-03 06:03:10Z bisson $
# Maintainer: Gaetan Bisson <bisson@archlinux.org>
# Contributor: Gerhard Brauer <gerhard.brauer@web.de>
pkgname=collectd
pkgver=5.1.0
pkgrel=3
pkgdesc='Daemon which collects system performance statistics periodically'
url='http://collectd.org/'
arch=('i686' 'x86_64')
license=('GPL')
optdepends=('curl: apache, ascent, curl, nginx, and write_http plugins'
'libdbi: dbi plugin'
'libesmtp: notify_email plugin'
'libgcrypt: encryption and authentication for network plugin'
'iptables: iptables plugin'
'libmemcached: memcachec plugin'
'libmysqlclient: mysql plugin'
'iproute2: netlink plugin'
'net-snmp: snmp plugin'
'libnotify: notify_desktop plugin'
'liboping: ping plugin'
'libpcap: dns plugin'
'perl: perl plugin'
'postgresql-libs: postgresql plugin'
'python2: python plugin'
'rrdtool: rrdtool and rrdcached plugins'
'lm_sensors: lm_sensors and sensors plugins'
'libvirt: libvirt plugin'
'libxml2: ascent and libvirt plugins'
'xmms: xmms plugin'
'yajl: curl_json plugin')
makedepends=('curl' 'libdbi' 'libesmtp' 'libgcrypt' 'iptables' 'libmemcached'
'libmysqlclient' 'iproute2' 'net-snmp' 'libnotify' 'liboping'
'libpcap' 'postgresql-libs' 'python2' 'rrdtool' 'lm_sensors'
'libvirt' 'libxml2' 'xmms' 'yajl')
depends=('libltdl')
source=("${url}files/${pkgname}-${pkgver}.tar.gz"
'rtnl_dump_filter.patch'
'libperl.patch'
'service'
'rc.d')
sha1sums=('55f17b17a10710641a9bf4e8c5332cef661cafcd'
'c92b8dacff0a71f2cc8645c2e350ff9bdc1cbd5f'
'245c098d121a4a05594553583310953b3a2f6461'
'b56907f532b9174e1b6995aadb518228d7464d3b'
'0f441718d5519cb043b1130e5a1d0379078adbcc')
backup=('etc/collectd.conf')
options=('!libtool')
install=install
build() {
cd "${srcdir}/${pkgname}-${pkgver}"
patch -p1 -i ../rtnl_dump_filter.patch
patch -p1 -i ../libperl.patch
autoconf
./configure \
--prefix=/usr \
--sysconfdir=/etc \
--localstatedir=/var \
--enable-static=no \
--with-python=/usr/bin/python2
make all
}
package() {
cd "${srcdir}/${pkgname}-${pkgver}"
make DESTDIR="${pkgdir}" install
install -Dm755 ../rc.d "${pkgdir}/etc/rc.d/${pkgname}"
install -Dm644 ../service "${pkgdir}"/usr/lib/systemd/system/collectd.service
install -Dm644 contrib/collectd2html.pl "${pkgdir}"/usr/share/collectd/collectd2html.pl
}
|
