blob: a9d85ff85aa558b801e13510bc125b3c1ce4e268 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
|
#$Id: PKGBUILD 79133 2012-10-31 00:23:46Z dwallace $
# Maintainer: Daniel Wallace <danielwallace at gtmanfred dot com>
# Contributor: Lucas De Marchi <lucas.de.marchi@gmail.com>
pkgname=connman
pkgver=1.9
pkgrel=2
pkgdesc="Wireless LAN network manager"
url="http://connman.net/"
arch=('i686' 'x86_64')
license=('GPL2')
depends=('dbus-core' 'iptables' 'glib2' 'gnutls')
conflicts=('openresolv')
optdepends=('bluez: Support for Bluetooth devices'
'wpa_supplicant: For WiFi devices')
makedepends=('bluez' 'wpa_supplicant' 'openconnect' 'openvpn')
options=('!libtool')
source=('connmand-daemon'
"http://www.kernel.org/pub/linux/network/${pkgname}/${pkgname}-${pkgver}.tar.bz2"
'allow_group_network.diff')
build() {
cd "${srcdir}/${pkgname}-${pkgver}"
patch -Np1 -i "${srcdir}/allow_group_network.diff"
./configure --prefix=/usr --sysconfdir=/etc --localstatedir=/var \
--with-systemdunitdir=/usr/lib/systemd/system \
--enable-threads \
--enable-openconnect \
--enable-openvpn \
--enable-polkit \
--enable-client
make
}
package(){
cd "${srcdir}/${pkgname}-${pkgver}"
make DESTDIR="${pkgdir}" install
install -Dm755 "$srcdir"/connmand-daemon "$pkgdir"/etc/rc.d/connmand
install -Dm755 "$srcdir/$pkgname-$pkgver/client/${pkgname}ctl" "$pkgdir/usr/sbin/${pkgname}ctl"
}
md5sums=('88ece7cbf1d0d289545ce4f8553fdab8'
'8196824f400719dd172222a355ad9592'
'a8d22ee089fb0ed725130d16ad393047')
|
