blob: 51bbdaeb5903ec886530b75ffa939c60eed32300 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
|
#$Id: PKGBUILD 102949 2013-12-24 22:58:06Z dwallace $
# Maintainer: Daniel Wallace <danielwallace at gtmanfred dot com>
# Contributor: Lucas De Marchi <lucas.de.marchi@gmail.com>
pkgname=connman
pkgver=1.20
pkgrel=1
pkgdesc="Wireless LAN network manager"
url="http://connman.net/"
arch=('i686' 'x86_64')
license=('GPL2')
depends=('dbus-core' 'iptables' 'gnutls' 'glib2')
conflicts=('openresolv')
optdepends=('bluez: Support for Bluetooth devices'
'wpa_supplicant: For WiFi devices'
'pptpclient: for ppp support')
makedepends=('bluez' 'wpa_supplicant' 'openconnect' 'openvpn' 'ppp')
source=("http://www.kernel.org/pub/linux/network/${pkgname}/${pkgname}-${pkgver}.tar.bz2"
'allow_group_network.diff')
md5sums=('5e4c7b61321994a772ddccbb5835684d'
'a8d22ee089fb0ed725130d16ad393047')
prepare(){
cd "${srcdir}/${pkgname}-${pkgver}"
patch -Np1 -i "${srcdir}/allow_group_network.diff"
}
build() {
cd "${srcdir}/${pkgname}-${pkgver}"
./configure --prefix=/usr --sysconfdir=/etc --localstatedir=/var \
--bindir=/usr/bin \
--sbindir=/usr/bin \
--with-systemdunitdir=/usr/lib/systemd/system \
--enable-threads \
--enable-pptp \
--enable-openconnect \
--enable-vpnc \
--enable-openvpn \
--enable-polkit \
--enable-client
make
}
package(){
make -C "${srcdir}/${pkgname}-${pkgver}" DESTDIR="${pkgdir}" install
install -Dm755 "$srcdir/$pkgname-$pkgver/client/${pkgname}ctl" "$pkgdir/usr/bin/${pkgname}ctl"
find "$pkgdir/usr" -name \*.service -exec sed -i 's/s\(bin\)/\1/' {} +
}
|
