blob: 812a0255c3f312f3724b910e28850b163be5bfe6 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
|
# $Id: PKGBUILD 87844 2013-04-08 09:22:21Z spupykin $
# Maintainer: Sergej Pupykin <pupykin.s+arch@gmail.com>
# Contributor: Jeff 'codemac' Mickey <jeff@archlinux.org>
# Contributor: Alexander Rødseth <rodseth@gmail.com>
pkgname=ejabberd
pkgver=2.1.12
pkgrel=1
pkgdesc="Jabber server written in Erlang"
arch=('x86_64' 'i686' 'mips64el')
url="http://www.ejabberd.im/"
license=("GPL")
depends=('expat' 'openssl' 'zlib' 'erlang' 'pam' 'iproute2')
backup=('etc/ejabberd/ejabberd.cfg'
'etc/ejabberd/ejabberdctl.cfg'
'etc/logrotate.d/ejabberd')
install=$pkgname.install
source=("http://www.process-one.net/downloads/ejabberd/${pkgver/_/-}/ejabberd-${pkgver}.tgz"
"$pkgname.logrotate"
"$pkgname"
"ejabberd.service")
md5sums=('7d49242cf04282f3c4cebfafa2cc2f46'
'f97c8a96160f30e0aecc9526c12e6606'
'2338a6230ce5f9f60be6dddcfa39bc7e'
'df32aa17e40a7bc5d9946d3ba6fe5e16')
build() {
cd "$srcdir/$pkgname-$pkgver/src"
./configure --prefix=/usr --sysconfdir=/etc --localstatedir=/var \
--enable-pam --enable-odbc
make
}
package() {
cd "$srcdir/$pkgname-$pkgver/src"
make DESTDIR="$pkgdir" install
install -D -m 0755 "$srcdir/$pkgname" "$pkgdir/etc/rc.d/$pkgname"
install -d "$pkgdir/var/lib/$pkgname"
install -D -m0644 "$srcdir/$pkgname.logrotate" "$pkgdir/etc/logrotate.d/$pkgname"
chmod ug+r "$pkgdir/etc/$pkgname/"*
chmod a+rx "$pkgdir/usr/sbin/ejabberdctl"
rm -rf "$pkgdir/var/lock"
install -Dm0644 $srcdir/ejabberd.service $pkgdir/usr/lib/systemd/system/ejabberd.service
}
# vim:set ts=2 sw=2 et:
|
